3 files changed, 74 insertions, 0 deletions
diff --git a/dev-python/dbus-fast/Manifest b/dev-python/dbus-fast/Manifest
new file mode 100644
index 000000000000..5e40a23d73fb
--- /dev/null
+++ b/dev-python/dbus-fast/Manifest
@@ -0,0 +1,3 @@
+DIST dbus-fast-2.24.4.gh.tar.gz 178320 BLAKE2B 790935c94b8c5984993bbbc7741cca1ab6c232e8a58266030318c774dcbdd77b3712fbb5ab3b3c6197f86eb8c0be0d8626e9dfcabf50a1a485be8d80334721fe SHA512 e08a1b8c028cf33f7055621b502ffdffb1d9c79875b9f9d05afca401cdc583ae97bb029706002ad0e94e2ce8ccf3a992fe9cc9c023e87f64d04bb581b2e9f263
+EBUILD dbus-fast-2.24.4.ebuild 1365 BLAKE2B 0032297b029f8afe9f914a14031df0c6057123cb9b3e6b2c7ce8c43744eb4c7adbbae4e04d2443bc1239457020d21b84cf0f31d2bc80e4193f361289f9cb1db0 SHA512 941d40095e271baa9b69235ee9f9a2bd51e92e06691557cb0b3962d18ddd7bfb941de6dadee145681986cac43ee50241b34805425e69a6722c27fd860ac1d9a1
+MISC metadata.xml 358 BLAKE2B b3e64afbcae1f0bf903b248c0da287bf2c6c5921d347c56bb63edc7ee266628750cde9bfd50ba4f1b6cdda84ff705dc0ce090bb4872233032163726b352cc454 SHA512 e2bcdb48456b29576690ccdca08a701915aee1f5e8857c35f6e950198c124cec283ed6d03dcdae1a2669dcb0244e9a4a4b6ea43d193b06738b09e081e060b9fb
diff --git a/dev-python/dbus-fast/dbus-fast-2.24.4.ebuild b/dev-python/dbus-fast/dbus-fast-2.24.4.ebuild
new file mode 100644
index 000000000000..bf290b3322cf
--- /dev/null
+++ b/dev-python/dbus-fast/dbus-fast-2.24.4.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="A faster version of dbus-next"
+HOMEPAGE="
+	https://github.com/bluetooth-devices/dbus-fast/
+	https://pypi.org/project/dbus-fast/
+"
+SRC_URI="
+	https://github.com/Bluetooth-Devices/dbus-fast/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+BDEPEND="
+	>=dev-python/cython-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-65.4.1[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/pycairo-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pygobject-3.42.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.19[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+export REQUIRE_CYTHON=1
+
+src_test() {
+	local dbus_params=(
+		$(dbus-daemon --session --print-address --fork --print-pid)
+	)
+	local -x DBUS_SESSION_BUS_ADDRESS=${dbus_params[0]}
+
+	virtx distutils-r1_src_test
+
+	kill "${dbus_params[1]}" || die
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# interface not found on this object: org.freedesktop.DBus.Debug.Stats
+		tests/client/test_signals.py::test_signals
+	)
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	nonfatal epytest -o addopts= -p asyncio || die
+}
diff --git a/dev-python/dbus-fast/metadata.xml b/dev-python/dbus-fast/metadata.xml
new file mode 100644
index 000000000000..584f534455fa
--- /dev/null
+++ b/dev-python/dbus-fast/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">bluetooth-devices/dbus-fast</remote-id>
+		<remote-id type="pypi">dbus-fast</remote-id>
+	</upstream>
+</pkgmetadata>