summaryrefslogtreecommitdiff
path: root/app-emulation
diff options
context:
space:
mode:
Diffstat (limited to 'app-emulation')
-rw-r--r--app-emulation/Manifest.gzbin21043 -> 21050 bytes
-rw-r--r--app-emulation/conmon/conmon-2.0.10.ebuild44
-rw-r--r--app-emulation/conmon/conmon-2.0.9.ebuild42
-rw-r--r--app-emulation/containers-storage/Manifest2
-rw-r--r--app-emulation/containers-storage/containers-storage-1.15.7.ebuild60
-rw-r--r--app-emulation/libpod/libpod-1.7.0.ebuild137
6 files changed, 285 insertions, 0 deletions
diff --git a/app-emulation/Manifest.gz b/app-emulation/Manifest.gz
index c42f1af7b02b..e827f0f69010 100644
--- a/app-emulation/Manifest.gz
+++ b/app-emulation/Manifest.gz
Binary files differ
diff --git a/app-emulation/conmon/conmon-2.0.10.ebuild b/app-emulation/conmon/conmon-2.0.10.ebuild
new file mode 100644
index 000000000000..094875d653de
--- /dev/null
+++ b/app-emulation/conmon/conmon-2.0.10.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_COMMIT="7a830be343876ac381c965c7429a7fb9b3d7a609"
+DESCRIPTION="An OCI container runtime monitor"
+HOMEPAGE="https://github.com/containers/conmon"
+SRC_URI="https://github.com/containers/conmon/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="systemd"
+
+RDEPEND="dev-libs/glib:=
+ systemd? ( sys-apps/systemd:= )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+src_prepare() {
+ default
+
+ if ! use systemd; then
+ sed -e 's| $(PKG_CONFIG) --exists libsystemd-journal | false |' \
+ -e 's| $(PKG_CONFIG) --exists libsystemd | false |' \
+ -i Makefile || die
+ fi
+}
+
+src_compile() {
+ emake GIT_COMMIT="${EGIT_COMMIT}" \
+ all
+}
+
+src_install() {
+ emake DESTDIR="${D}" \
+ PREFIX="/usr" \
+ install
+ dodir /usr/libexec/podman
+ ln "${ED}/usr/"{bin,libexec/podman}/conmon || die
+ dodoc README.md
+}
diff --git a/app-emulation/conmon/conmon-2.0.9.ebuild b/app-emulation/conmon/conmon-2.0.9.ebuild
new file mode 100644
index 000000000000..94ebc62d9c17
--- /dev/null
+++ b/app-emulation/conmon/conmon-2.0.9.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_COMMIT="60b42f20f222df9da07a01ee444327348b9f54ee"
+DESCRIPTION="An OCI container runtime monitor"
+HOMEPAGE="https://github.com/containers/conmon"
+SRC_URI="https://github.com/containers/conmon/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="systemd"
+
+RDEPEND="dev-libs/glib:=
+ systemd? ( sys-apps/systemd:= )"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+ default
+
+ if ! use systemd; then
+ sed -e 's| $(PKG_CONFIG) --exists libsystemd-journal | false |' \
+ -e 's| $(PKG_CONFIG) --exists libsystemd | false |' \
+ -i Makefile || die
+ fi
+}
+
+src_compile() {
+ emake GIT_COMMIT="${EGIT_COMMIT}" \
+ all
+}
+
+src_install() {
+ emake DESTDIR="${D}" \
+ PREFIX="/usr" \
+ install
+ dodir /usr/libexec/podman
+ ln "${ED}/usr/"{bin,libexec/podman}/conmon || die
+ dodoc README.md
+}
diff --git a/app-emulation/containers-storage/Manifest b/app-emulation/containers-storage/Manifest
index 671599512f95..505621957e19 100644
--- a/app-emulation/containers-storage/Manifest
+++ b/app-emulation/containers-storage/Manifest
@@ -1,5 +1,7 @@
DIST containers-storage-1.15.1.tar.gz 6037975 BLAKE2B e6d0d9adae829fd3d8cb40aa124b7149ee56ed13650b0dc57ba316ab2f03e754bdbb3e566c199b7768c612b159fa3051db39cd90127f4676255e452863aa7e24 SHA512 ea017e7dec840e5794f0ae61ebfc0cbf55b8de2c237286371eef3fd1808809e2bb149f08ba62126c741e0811839bf0af8f97bbda32e715132e42905f2ebd3a6c
DIST containers-storage-1.15.2.tar.gz 6199303 BLAKE2B 76b950892d4a3016a6df2223c66d9720334205bb1c1b6d18f09b984df9c967391329a970d9d927206f37d4557fc6f4b6c366cb6f35711d2a7d8842f7e3bf7221 SHA512 b152e85e8ebdc5016955287c289390568865d60b2b034e5d32eaa3d11d775a12788465246ff7b75cd8a079758f5d2fd90bd1443191f6a089f54862951a26cdae
+DIST containers-storage-1.15.7.tar.gz 6202610 BLAKE2B 2eeeb124c0ce22b5f80aced4b0a9b8d541a00d532458c64e8a017b6d7e7364b90cf798db81b9dfe36af3a25e70383529f7e2ee649750ceaff753b9327a1713c8 SHA512 25317ec5a002274422cab7ab3928ac5e9776751bc2c7c17800def2f0f918f2356c074f1914056e24bd900fb4d951d6259461f9fe3fd7c6d669ca2e78b2c70d12
EBUILD containers-storage-1.15.1.ebuild 1471 BLAKE2B 9990d85a89853309e601d27cb26093e7c9255b680907a952936ea234ff2a2974f9e78100b8a18b73f58cc3984a6efd387f00ec277511fb4052c09c17330c329c SHA512 04e5fed27bef4254b8ad07e6169f1eee023ff9693c4d4eddebf1f87f50e8bb4f70eee0b42585faa24cd1aaad1a909006135869dff4274533b8323c30a50238ad
EBUILD containers-storage-1.15.2.ebuild 1471 BLAKE2B 9990d85a89853309e601d27cb26093e7c9255b680907a952936ea234ff2a2974f9e78100b8a18b73f58cc3984a6efd387f00ec277511fb4052c09c17330c329c SHA512 04e5fed27bef4254b8ad07e6169f1eee023ff9693c4d4eddebf1f87f50e8bb4f70eee0b42585faa24cd1aaad1a909006135869dff4274533b8323c30a50238ad
+EBUILD containers-storage-1.15.7.ebuild 1479 BLAKE2B f5fa031ee42b10c7dc41fc20a37a61436f3e4e6ee68fc33b37d6cd2bb0989e274d13a9b3165ee742da4c83a6ba127541905aebea4e60a2cd6038b632e4fa4847 SHA512 4bdb4af924e1e70851e1757f172917a779134f869677bf810ec45596e84142f48a6c97ca6ca9080c849da36d8a70c1c10e365bf692176f02fce1d9a8a4dd1cce
MISC metadata.xml 603 BLAKE2B 97f54132ebad8af6ff29ffd35644f68faeca3f387025e6bfd7529e7d61582e7bbd8f4279c3608b6b8187e1f6a78c552d1bb9e828cfb2f6fe5fa6710e0730d2f2 SHA512 f65876cdaac00b0d5ed7524467b9cde201da0a3fdf17d959bb19bc2d98344ca013b93dd0d2ebbb24b585a9754b8d06711e0085092a3820bdfe238e26a64d765b
diff --git a/app-emulation/containers-storage/containers-storage-1.15.7.ebuild b/app-emulation/containers-storage/containers-storage-1.15.7.ebuild
new file mode 100644
index 000000000000..1c7bf5f6ff65
--- /dev/null
+++ b/app-emulation/containers-storage/containers-storage-1.15.7.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit go-module
+
+KEYWORDS="~amd64"
+DESCRIPTION="containers/storage library"
+HOMEPAGE="https://github.com/containers/storage"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+IUSE="btrfs +device-mapper test"
+EGO_PN="${HOMEPAGE#*//}"
+EGIT_COMMIT="v${PV}"
+SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+RDEPEND="
+ btrfs? ( sys-fs/btrfs-progs )
+ device-mapper? ( sys-fs/lvm2:= )"
+DEPEND="${RDEPEND}
+ dev-go/go-md2man
+ test? (
+ sys-fs/btrfs-progs
+ sys-fs/lvm2
+ sys-apps/util-linux
+ )"
+RESTRICT="test"
+
+S=${WORKDIR}/${P#containers-}
+
+src_prepare() {
+ default
+
+ sed -e 's:GO111MODULE=off:GO111MODULE=on:' -i Makefile || die
+
+ [[ -f hack/btrfs_tag.sh ]] || die
+ use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+ "hack/btrfs_tag.sh" || die; }
+
+ [[ -f hack/libdm_tag.sh ]] || die
+ use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
+ "hack/libdm_tag.sh" || die; }
+}
+
+src_compile() {
+ export -n GOCACHE GOPATH XDG_CACHE_HOME #678856
+ emake containers-storage docs
+}
+
+src_install() {
+ dobin "${PN}"
+ while read -r -d ''; do
+ mv "${REPLY}" "${REPLY%.1}" || die
+ done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
+ find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
+}
+
+src_test() {
+ env -u GOFLAGS unshare -m emake local-test-unit || die
+}
diff --git a/app-emulation/libpod/libpod-1.7.0.ebuild b/app-emulation/libpod/libpod-1.7.0.ebuild
new file mode 100644
index 000000000000..5ccc860cc393
--- /dev/null
+++ b/app-emulation/libpod/libpod-1.7.0.ebuild
@@ -0,0 +1,137 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_COMMIT="b7ce1157b00af09f4a09e39b377aa3abff46ee05"
+
+inherit bash-completion-r1 flag-o-matic go-module
+
+DESCRIPTION="Library and podman tool for running OCI-based containers in Pods"
+HOMEPAGE="https://github.com/containers/libpod/"
+SRC_URI="https://github.com/containers/libpod/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT MPL-2.0"
+SLOT="0"
+
+KEYWORDS="~amd64"
+IUSE="apparmor btrfs ostree +rootless selinux"
+REQUIRED_USE="!ostree"
+RESTRICT="test"
+
+COMMON_DEPEND="
+ app-crypt/gpgme:=
+ >=app-emulation/conmon-2.0.0
+ || ( >=app-emulation/runc-1.0.0_rc6 app-emulation/crun )
+ dev-libs/libassuan:=
+ dev-libs/libgpg-error:=
+ sys-fs/lvm2
+ sys-libs/libseccomp:=
+
+ apparmor? ( sys-libs/libapparmor )
+ btrfs? ( sys-fs/btrfs-progs )
+ rootless? ( app-emulation/slirp4netns )
+ selinux? ( sys-libs/libselinux:= )
+"
+DEPEND="
+ ${COMMON_DEPEND}
+ dev-go/go-md2man"
+RDEPEND="${COMMON_DEPEND}"
+
+src_prepare() {
+ default
+
+ # Disable installation of python modules here, since those are
+ # installed by separate ebuilds.
+ sed -e '/^GIT_.*/d' \
+ -e 's:GO111MODULE=off:GO111MODULE=on:' \
+ -e 's/$(GO) build/$(GO) build -v -work -x/' \
+ -e 's/^\(install:.*\) install\.python$/\1/' \
+ -i Makefile || die
+
+ sed -e 's|OUTPUT="${CIRRUS_TAG:.*|OUTPUT='v${PV}'|' \
+ -i hack/get_release_info.sh || die
+}
+
+src_compile() {
+ # Filter unsupported linker flags
+ filter-flags '-Wl,*'
+
+ [[ -f hack/apparmor_tag.sh ]] || die
+ if use apparmor; then
+ echo -e "#!/bin/sh\necho apparmor" > hack/apparmor_tag.sh || die
+ else
+ echo -e "#!/bin/sh\ntrue" > hack/apparmor_tag.sh || die
+ fi
+
+ [[ -f hack/btrfs_installed_tag.sh ]] || die
+ if use btrfs; then
+ echo -e "#!/bin/sh\ntrue" > hack/btrfs_installed_tag.sh || die
+ else
+ echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
+ hack/btrfs_installed_tag.sh || die
+ fi
+
+ [[ -f hack/selinux_tag.sh ]] || die
+ if use selinux; then
+ echo -e "#!/bin/sh\necho selinux" > hack/selinux_tag.sh || die
+ else
+ echo -e "#!/bin/sh\ntrue" > hack/selinux_tag.sh || die
+ fi
+
+ export -n GOCACHE GOPATH XDG_CACHE_HOME
+ GOBIN="${S}/bin" \
+ emake all \
+ GIT_BRANCH=master \
+ GIT_BRANCH_CLEAN=master \
+ COMMIT_NO="${EGIT_COMMIT}" \
+ GIT_COMMIT="${EGIT_COMMIT}"
+}
+
+src_install() {
+ emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+ insinto /etc/containers
+ newins test/registries.conf registries.conf.example
+ newins test/policy.json policy.json.example
+
+ insinto /usr/share/containers
+ doins seccomp.json
+
+ newinitd "${FILESDIR}"/podman.initd podman
+
+ insinto /etc/logrotate.d
+ newins "${FILESDIR}/podman.logrotated" podman
+
+ dobashcomp completions/bash/*
+
+ keepdir /var/lib/containers
+}
+
+pkg_preinst() {
+ LIBPOD_ROOTLESS_UPGRADE=false
+ if use rootless; then
+ has_version 'app-emulation/libpod[rootless]' || LIBPOD_ROOTLESS_UPGRADE=true
+ fi
+}
+
+pkg_postinst() {
+ local want_newline=false
+ if [[ ! ( -e ${EROOT%/*}/etc/containers/policy.json && -e ${EROOT%/*}/etc/containers/registries.conf ) ]]; then
+ elog "You need to create the following config files:"
+ elog "/etc/containers/registries.conf"
+ elog "/etc/containers/policy.json"
+ elog "To copy over default examples, use:"
+ elog "cp /etc/containers/registries.conf{.example,}"
+ elog "cp /etc/containers/policy.json{.example,}"
+ want_newline=true
+ fi
+ if [[ ${LIBPOD_ROOTLESS_UPGRADE} == true ]] ; then
+ ${want_newline} && elog ""
+ elog "For rootless operation, you need to configure subuid/subgid"
+ elog "for user running podman. In case subuid/subgid has only been"
+ elog "configured for root, run:"
+ elog "usermod --add-subuids 1065536-1131071 <user>"
+ elog "usermod --add-subgids 1065536-1131071 <user>"
+ want_newline=true
+ fi
+}
generated by cgit v1.2.3 (git 2.25.1) at 2024-05-22 07:33:56 +0000