gentoo resync : 21.07.2018

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-python/pyhamcrest/pyhamcrest-1.9.0-r1.ebuild b/dev-python/pyhamcrest/pyhamcrest-1.9.0-r1.ebuild
new file mode 100644
index 000000000000..772b9f693b9e
--- /dev/null
+++ b/dev-python/pyhamcrest/pyhamcrest-1.9.0-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6,7} )
+
+inherit distutils-r1
+
+MY_PN="PyHamcrest"
+
+DESCRIPTION="Hamcrest framework for matcher objects"
+HOMEPAGE="https://github.com/hamcrest/PyHamcrest"
+SRC_URI="https://github.com/hamcrest/PyHamcrest/archive/V${PV}.tar.gz -> ${MY_PN}-${PV}.gh.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~amd64-fbsd"
+IUSE="doc examples test"
+
+RDEPEND=">=dev-python/six-1.4[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/sphinx-1.2.2[${PYTHON_USEDEP}]
+		dev-python/sphinx_rtd_theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		>=dev-python/pytest-2.6[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+	)"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_prepare_all() {
+	# enables coverage testing which we don't want
+	rm pytest.ini || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && esetup.py build_sphinx
+}
+
+python_test() {
+	py.test -vv || die "Tests failed under ${EPYTHON}"
+	"${PYTHON}" tests/object_import.py || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/_build/html/. )
+	use examples && dodoc -r examples
+
+	distutils-r1_python_install_all
+}