gentoo auto-resync : 01:07:2023 - 13:45:28

2 files changed, 234 insertions, 0 deletions

diff --git a/dev-python/pandas/Manifest b/dev-python/pandas/Manifest
index 72bc00a1549f..7e545bce40fd 100644
--- a/dev-python/pandas/Manifest
+++ b/dev-python/pandas/Manifest
@@ -4,10 +4,12 @@ DIST pandas-1.5.3.tar.gz 5203060 BLAKE2B 846a6caa8ead6a2556303494f92e2091582d8fc
 DIST pandas-2.0.0.tar.gz 5271334 BLAKE2B 80782f407cb93866ca445518f45ea36e081b789d72ef597f6501746c41c1bb1000f183a7352e04194401d59c523ab796373445cddd42166c19f9d8cac522f426 SHA512 6a960275e03b1171cde1085cc0a853273c35377809eddc75c82bb6deb06c3ed499265efe88012771c86f86872a6f6b2d3e218bcb209259dcfc46781367cd2f51
 DIST pandas-2.0.1.tar.gz 5279594 BLAKE2B 84dbab2c6079c77eb7f367aaabc2f4d0c8205a3d8bd2e4db9f071cf1d25c53a32f91679ae7ff56e21e76447a675b4f4e7c660708f3e2a7a56753137018239dd6 SHA512 ecb150045c82ef649fcdd940c3b45884f0f9f8a51402b331fc247c148f669fe7bece33b331d1ddac84b7fef39d096ad7488057d3772e74d087ea26bb9cac3994
 DIST pandas-2.0.2.tar.gz 5290568 BLAKE2B 26eb9db6c1c2b4f9ae31b3aae09fc4db930d13e59b2037261eb2e3006a04402bc0a502febe29c0a3e071953bfbf4efac56eddf14bca2e22be0128e82d649a958 SHA512 feda98a2f83865d0ecb3fc2c37c927ddcd075f621954758eee26f1e9a0d9d1367ce790972f4ee3fb5928731ac157533345635fed390fdc306541047ab47fda60
+DIST pandas-2.0.3.tar.gz 5284455 BLAKE2B 42db94dd031ca10c87434f4f903509abf0e6c2c3e3561ae5f5db6db09ebf95996aaa34e1f98a3e33f2b687c69dd1b38dc136d5928da2c096756b6755bf9b31c0 SHA512 bee3640521692545cb063b78c85f5ab90817c8029156f97856af4c9edfcc3e13596b48c4c1b4060c92e7e75b3b876d0734f7c1e3b2096d44c52ec09372c99d2e
 EBUILD pandas-1.5.1.ebuild 6844 BLAKE2B 6ca6773bdbe62afb23995ff7da8733c57ab74f1d0c1258b60430e37cd66b9c92a0939dcb83c85570bd9f36301674ce5a26a3c916d841cf759c4076b5d9370e35 SHA512 9aa26f4e18b3272a8333a8a04db41c18e3dba7380a46089c9465a74c03324eb89fa456fb38db8cd3cbda82d70e179b5bc1b6962a9dc67e0b848dbb519a866cfa
 EBUILD pandas-1.5.2.ebuild 6845 BLAKE2B 48888c3de9424339f613708616417f4a228728984ec69fac28b24847f892f3fc103950cee1066e8e3b4da2562f977d9bf1ca2d20ed49e0754f7fa0428a086b6a SHA512 73eb7ced8dd88578f4b45dbc99c4b3f81a00866a26016bb858833bb296e782399fe76d2bd94a3e444b244cbb759c8716857e6cd4a8927a0f119968075c1f40b9
 EBUILD pandas-1.5.3.ebuild 7152 BLAKE2B f6b01a61457a1f7b8da40cdf70b254d2977dc75bee93356f497bc99f7beb0beeefc0de05a38cbd5458fed4de33d5bee885abc52aa17a341fa772575d2c8445c1 SHA512 945d9b70ace8aaca8d652d9cfef9de66cbaa8803aaa01ee1ae6d4529ec93b7757899b884d86afcf4cdde81ab7520c9d5bfe3f0078ab03cd4a4012f0f0c08cb2b
 EBUILD pandas-2.0.0.ebuild 7485 BLAKE2B f8e46eb256077d91844b5c158aed257f4072e57df6f2cde7a9311e168fb80ef762d78b0679e2c06c9402df5cd3f6bc04d03df3295a1d0f1333f9cbd13026d33b SHA512 cc8821469cd3f348ee8f827d3d4c1f0441930a8b899f446dc4cc2c847014036ff09bcf59405be87e88f471c4aba495c3f0a9b1bd17fae9fb00e5320d00dd319b
 EBUILD pandas-2.0.1.ebuild 7523 BLAKE2B 06f0c8337b31b89535745057efe19d192f6fcd4cb5d1e0eda8b3f3bc809533618cad487885159a04b8475b413e87640be62b376bac3364a2fbee83f49a91691f SHA512 9d7aa683cf0bae4f847d1e28eaf5b1100bfffad292b8a95d5a857e21307a82a95058c13957d3452730c88f31d1cb2aa28990d10457e1b28a779cf567ee03a1f4
 EBUILD pandas-2.0.2.ebuild 7601 BLAKE2B 806c707327c80b0e914e4a6e804aab5f24f7ca1fd79fe3ac15dbc1cba63ca65d8b7df97b2d78722f8526e3a32c07b8f31bb8ea418d886387fb711a6090453cb9 SHA512 98960556415b55c48f9123006791066e22cb8ac199c5571926b03ac709057036fefab6c9c4f3361b2cd0adaba59d51caa8a327d98327feda9fff79f2c78c2351
+EBUILD pandas-2.0.3.ebuild 7844 BLAKE2B c8f5fb0f55996ed2cdea752fbc3b30dc09317c7d26263736b776d1d4e3ef71771d1131a9fc86c24636342063a55654a6597b30e71b6f42db758fd86e61d48693 SHA512 97e6a9e12e4c16e33b41fc1dd6bd44e784883d8130ac7e7cf309164dcb3cc1711796127d02c9261812750f1d1bf655bfd2cd1487118f653a8c9cff81a2e22bd9
 MISC metadata.xml 920 BLAKE2B d6bd854acdd851d578038657d91adaedf4f220dbdc5905ebba5e35e74437c6d5bc2384061f7796a6f359aa128c526485635debfd0e1a9646d09daed740167c87 SHA512 dcd949e89cae9df918acb3cf8be5ad8c396ee5e646d2179aa2b646fafa15ffc11e9ccf853df8d7fdcc787f88ce7063639d8d87715aaba943774edc8ad98b540a
diff --git a/dev-python/pandas/pandas-2.0.3.ebuild b/dev-python/pandas/pandas-2.0.3.ebuild
new file mode 100644
index 000000000000..9112daf38f27
--- /dev/null
+++ b/dev-python/pandas/pandas-2.0.3.ebuild
@@ -0,0 +1,232 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} )
+PYTHON_REQ_USE="threads(+)"
+
+VIRTUALX_REQUIRED="manual"
+
+inherit distutils-r1 multiprocessing optfeature virtualx
+
+DESCRIPTION="Powerful data structures for data analysis and statistics"
+HOMEPAGE="
+	https://pandas.pydata.org/
+	https://github.com/pandas-dev/pandas/
+	https://pypi.org/project/pandas/
+"
+SRC_URI="
+	https://github.com/pandas-dev/pandas/releases/download/v${PV}/${P}.tar.gz
+"
+S=${WORKDIR}/${P/_/}
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc full-support minimal test X"
+RESTRICT="!test? ( test )"
+
+RECOMMENDED_DEPEND="
+	>=dev-python/bottleneck-1.3.2[${PYTHON_USEDEP}]
+	>=dev-python/numexpr-2.7.1[${PYTHON_USEDEP}]
+"
+
+# TODO: add pandas-gbq to the tree
+# TODO: Re-add dev-python/statsmodel[python3_11] dep once it supports python3_11
+# https://github.com/statsmodels/statsmodels/issues/8287
+OPTIONAL_DEPEND="
+	>=dev-python/beautifulsoup4-4.9.3[${PYTHON_USEDEP}]
+	dev-python/blosc[${PYTHON_USEDEP}]
+	>=dev-python/html5lib-1.1[${PYTHON_USEDEP}]
+	>=dev-python/jinja-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.6.3[${PYTHON_USEDEP}]
+	>=dev-python/matplotlib-3.6.1[${PYTHON_USEDEP}]
+	>=dev-python/openpyxl-3.0.7[${PYTHON_USEDEP}]
+	>=dev-python/pytables-3.6.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.4.16[${PYTHON_USEDEP}]
+	>=dev-python/tabulate-0.8.9[${PYTHON_USEDEP}]
+	>=dev-python/xarray-0.21.0[${PYTHON_USEDEP}]
+	>=dev-python/xlrd-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/xlsxwriter-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/xlwt-1.3.0[${PYTHON_USEDEP}]
+	!hppa? (
+		$(python_gen_cond_dep '
+			dev-python/statsmodels[${PYTHON_USEDEP}]
+		' python3_{8..10} )
+		>=dev-python/scipy-1.7.1[${PYTHON_USEDEP}]
+	)
+	X? (
+		|| (
+			>=dev-python/PyQt5-5.15.1[${PYTHON_USEDEP}]
+			>=dev-python/QtPy-2.2.0[${PYTHON_USEDEP}]
+			x11-misc/xclip
+			x11-misc/xsel
+		)
+	)
+"
+DEPEND="
+	>=dev-python/numpy-1.23.2[${PYTHON_USEDEP}]
+"
+COMMON_DEPEND="
+	${DEPEND}
+	>=dev-python/python-dateutil-2.8.2[${PYTHON_USEDEP}]
+	>=dev-python/pytz-2020.1[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	${COMMON_DEPEND}
+	>=dev-python/cython-0.29.33[${PYTHON_USEDEP}]
+	>=dev-python/versioneer-0.28[${PYTHON_USEDEP}]
+	doc? (
+		${VIRTUALX_DEPEND}
+		>=dev-python/beautifulsoup4-4.9.3[${PYTHON_USEDEP}]
+		>=dev-python/html5lib-1.1[${PYTHON_USEDEP}]
+		dev-python/ipython[${PYTHON_USEDEP}]
+		>=dev-python/lxml-4.6.3[${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-3.6.1[${PYTHON_USEDEP}]
+		dev-python/nbsphinx[${PYTHON_USEDEP}]
+		>=dev-python/numpydoc-0.9.1[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-3.0.7[${PYTHON_USEDEP}]
+		>=dev-python/pytables-3.6.1[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/rpy[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		>=dev-python/xlrd-2.0.1[${PYTHON_USEDEP}]
+		dev-python/xlwt[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		virtual/pandoc
+		x11-misc/xclip
+	)
+	test? (
+		${VIRTUALX_DEPEND}
+		${RECOMMENDED_DEPEND}
+		${OPTIONAL_DEPEND}
+		>=dev-python/beautifulsoup4-4.9.3[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.34.2[${PYTHON_USEDEP}]
+		>=dev-python/openpyxl-3.0.7[${PYTHON_USEDEP}]
+		>=dev-python/pymysql-1.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-7.3.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-asyncio-0.17.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-xdist-2.2.0[${PYTHON_USEDEP}]
+		>=dev-python/psycopg-2.8.6:2[${PYTHON_USEDEP}]
+		>=dev-python/xlsxwriter-1.4.3[${PYTHON_USEDEP}]
+		x11-misc/xclip
+		x11-misc/xsel
+	)
+"
+# dev-python/statsmodels invokes a circular dep
+#  hence rm from doc? ( ), again
+RDEPEND="
+	${COMMON_DEPEND}
+	!minimal? ( ${RECOMMENDED_DEPEND} )
+	full-support? ( ${OPTIONAL_DEPEND} )
+"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/^              'sphinx.ext.intersphinx',/d" \
+		-i doc/source/conf.py || die
+
+	# unnecessary with system tzdata
+	sed -i -e '/tzdata/d' pyproject.toml || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile() {
+	distutils-r1_python_compile -j1
+}
+
+python_compile_all() {
+	# To build docs the need be located in $BUILD_DIR,
+	# else PYTHONPATH points to unusable modules.
+	if use doc; then
+		cd "${BUILD_DIR}"/lib || die
+		cp -ar "${S}"/doc . && cd doc || die
+		LANG=C PYTHONPATH=. virtx ${EPYTHON} make.py html
+	fi
+}
+
+src_test() {
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# test for rounding errors, fails if we have better precision
+		# e.g. on amd64 with FMA or on arm64
+		# https://github.com/pandas-dev/pandas/issues/38921
+		pandas/tests/window/test_rolling.py::test_rolling_var_numerical_issues
+
+		# TODO
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated
+		pandas/tests/api/test_api.py::TestTesting::test_util_testing_deprecated_direct
+		pandas/tests/io/test_clipboard.py::TestClipboard::test_raw_roundtrip
+		pandas/tests/copy_view/test_internals.py::test_switch_options
+
+		# TODO: xdist?
+		pandas/tests/test_expressions.py::TestExpressions::test_run_binary
+
+		# TODO: these require a running db server
+		pandas/tests/io/test_sql.py::TestMySQLAlchemy
+		pandas/tests/io/test_sql.py::TestMySQLAlchemyConn
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemy
+		pandas/tests/io/test_sql.py::TestPostgreSQLAlchemyConn
+
+		# OOMs
+		pandas/tests/io/parser/test_c_parser_only.py::test_bytes_exceed_2gb
+
+		# xarray version incompatibility
+		pandas/tests/test_downstream.py::test_xarray_cftimeindex_nearest
+
+		# warning from dask
+		pandas/tests/test_downstream.py::test_construct_dask_float_array_int_dtype_match_ndarray
+
+		# TODO: mpl incompatibility?
+		pandas/tests/plotting/frame/test_frame.py::TestDataFramePlots::test_plain_axes
+
+		# crashes
+		pandas/tests/io/pytables/test_file_handling.py::test_complibs
+
+		# deprecation warning
+		pandas/tests/io/pytables/test_retain_attributes.py::test_retain_index_attributes2
+
+		# TODO
+		pandas/tests/tseries/offsets/test_year.py::test_add_out_of_pydatetime_range
+	)
+
+	local -x LC_ALL=C.UTF-8
+	cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
+	"${EPYTHON}" -c "import pandas; pandas.show_versions()" || die
+	epytest pandas --skip-slow --skip-network -m "not single" \
+		-n "$(makeopts_jobs)" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	if use doc; then
+		dodoc -r "${BUILD_DIR}"/lib/doc/build/html
+		einfo "An initial build of docs is absent of references to statsmodels"
+		einfo "due to circular dependency. To have them included, emerge"
+		einfo "statsmodels next and re-emerge pandas with USE doc"
+	fi
+
+	distutils-r1_python_install_all
+}
+
+pkg_postinst() {
+	optfeature "accelerating certain types of NaN evaluations, using specialized cython routines to achieve large speedups." dev-python/bottleneck
+	optfeature "accelerating certain numerical operations, using multiple cores as well as smart chunking and caching to achieve large speedups" ">=dev-python/numexpr-2.1"
+	optfeature "needed for pandas.io.html.read_html" dev-python/beautifulsoup4 dev-python/html5lib dev-python/lxml
+	optfeature "for msgpack compression using blosc" dev-python/blosc
+	optfeature "Template engine for conditional HTML formatting" dev-python/jinja
+	optfeature "Plotting support" dev-python/matplotlib
+	optfeature "Needed for Excel I/O" ">=dev-python/openpyxl-3.0.7" dev-python/xlsxwriter dev-python/xlrd dev-python/xlwt
+	optfeature "necessary for HDF5-based storage" ">=dev-python/pytables-3.6.1"
+	optfeature "R I/O support" dev-python/rpy
+	optfeature "Needed for parts of pandas.stats" dev-python/statsmodels
+	optfeature "SQL database support" ">=dev-python/sqlalchemy-1.4.16"
+	optfeature "miscellaneous statistical functions" dev-python/scipy
+	optfeature "necessary to use pandas.io.clipboard.read_clipboard support" dev-python/PyQt5 dev-python/QtPy dev-python/pygtk x11-misc/xclip x11-misc/xsel
+}