gentoo auto-resync : 24:09:2022 - 11:31:39

1 files changed, 47 insertions, 0 deletions

diff --git a/dev-python/contourpy/contourpy-1.0.5.ebuild b/dev-python/contourpy/contourpy-1.0.5.ebuild
new file mode 100644
index 000000000000..9ccea39952a2
--- /dev/null
+++ b/dev-python/contourpy/contourpy-1.0.5.ebuild
@@ -0,0 +1,47 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python library for calculating contours in 2D quadrilateral grids"
+HOMEPAGE="
+	https://pypi.org/project/contourpy/
+	https://github.com/contourpy/contourpy/
+"
+SRC_URI="
+	https://github.com/contourpy/contourpy/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	>=dev-python/numpy-1.16[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.6[${PYTHON_USEDEP}]
+	test? (
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local EPYTEST_IGNORE=(
+		# linters
+		tests/test_codebase.py
+	)
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	# threaded algorithms are known to be broken
+	# https://github.com/contourpy/contourpy/issues/163
+	epytest -k "not threaded and not threads"
+}