blob: 1fb05e0961025143a7a628eeb29ba7ebd0c0c7f6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake xdg
if [[ ${PV} = *9999* ]] ; then
EGIT_BRANCH="develop"
EGIT_REPO_URI="https://github.com/insilmaril/${PN}.git"
inherit git-r3
else
COMMIT="d1ba122d89c1c580f26f3535d264250a4d5d6b64"
SRC_URI="https://github.com/insilmaril/${PN}/archive/develop/${COMMIT}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-develop"
KEYWORDS="~amd64 ~x86"
fi
DESCRIPTION="View Your Mind, a mindmap tool"
HOMEPAGE="https://www.insilmaril.de/vym/"
LICENSE="GPL-2"
SLOT="0"
IUSE="dbus"
RDEPEND="
dev-qt/qtbase:6[dbus?,gui,network,ssl,widgets,xml]
dev-qt/qtdeclarative:6
dev-qt/qtsvg:6
"
DEPEND="${RDEPEND}"
BDEPEND="dev-qt/qttools:6[linguist]"
PATCHES=(
# fix install dir for doc, remove gzipped man, set VYM_DOCDIR
"${FILESDIR}"/${PN}-2.9-docdir.patch
)
src_prepare() {
cmake_src_prepare
gunzip doc/vym.1.gz || die
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package dbus DBus1)
-DCMAKE_INSTALL_DATAROOTDIR="share/${PN}"
)
cmake_src_configure
}
src_install() {
doman doc/vym.1
cmake_src_install
}
|
