blob: 9901f81c14fc7207e088a6f72541b55ddb5bea76 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="7"
PYTHON_COMPAT=( python3_{7..9} )
inherit autotools systemd python-r1
DESCRIPTION="Varnish is a state-of-the-art, high-performance HTTP accelerator"
HOMEPAGE="https://varnish-cache.org/"
SRC_URI="http://varnish-cache.org/_downloads/${P}.tgz"
LICENSE="BSD-2 GPL-2"
SLOT="0/2"
KEYWORDS="~amd64 ~mips ~ppc ~ppc64 ~x86"
IUSE="jemalloc jit static-libs"
CDEPEND="
sys-libs/readline:0=
dev-libs/libpcre[jit?]
jemalloc? ( dev-libs/jemalloc )
sys-libs/ncurses:0="
#varnish compiles stuff at run time
RDEPEND="
${PYTHON_DEPS}
${CDEPEND}
acct-user/varnish
acct-group/varnish
sys-devel/gcc"
DEPEND="
${CDEPEND}
dev-python/docutils
dev-python/sphinx
virtual/pkgconfig"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RESTRICT="test" #315725
PATCHES=(
"${FILESDIR}/varnish-6.5.1-autoconf-2.70.patch" #751190
)
src_prepare() {
# Remove -Werror bug #528354
sed -i -e 's/-Werror\([^=]\)/\1/g' configure.ac
# Upstream doesn't put varnish.m4 in the m4/ directory
# We link because the Makefiles look for the file in
# the original location
ln -sf ../varnish.m4 m4/varnish.m4
default
eautoreconf
}
src_configure() {
local myeconfargs=(
$(use_enable static-libs static)
$(use_enable jit pcre-jit)
$(use_with jemalloc)
)
econf "${myeconfargs[@]}"
}
src_install() {
emake DESTDIR="${D}" install
python_replicate_script "${D}/usr/share/varnish/vmodtool.py"
newinitd "${FILESDIR}"/varnishlog.initd varnishlog
newconfd "${FILESDIR}"/varnishlog.confd varnishlog
newinitd "${FILESDIR}"/varnishncsa.initd varnishncsa
newconfd "${FILESDIR}"/varnishncsa.confd varnishncsa
newinitd "${FILESDIR}"/varnishd.initd-r4 varnishd
newconfd "${FILESDIR}"/varnishd.confd-r4 varnishd
insinto /etc/logrotate.d/
newins "${FILESDIR}/varnishd.logrotate-r2" varnishd
diropts -m750
keepdir /var/lib/varnish
keepdir /var/log/varnish
systemd_dounit "${FILESDIR}/${PN}d.service"
insinto /etc/varnish/
doins lib/libvmod_std/vmod_std.vcc
doins etc/example.vcl
dodoc README.rst
dodoc doc/changes.rst
fowners root:varnish /etc/varnish/
fowners varnish:varnish /var/lib/varnish/
fperms 0750 /var/lib/varnish/ /etc/varnish/
}
|
