blob: ec5f9c97a2d4ec18b7847a78b7f908f115c02772 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools systemd toolchain-funcs
DESCRIPTION="Simple FastCGI wrapper for CGI scripts (CGI support for nginx)"
HOMEPAGE="https://github.com/gnosek/fcgiwrap"
if [[ ${PV} == *_p* ]] ; then
FCGIWRAP_COMMIT="99c942c90063c73734e56bacaa65f947772d9186"
SRC_URI="https://github.com/gnosek/fcgiwrap/archive/${FCGIWRAP_COMMIT}.tar.gz -> ${P}.gh.tar.gz"
S="${WORKDIR}"/${PN}-${FCGIWRAP_COMMIT}
else
# https://github.com/gnosek/fcgiwrap/issues/31
SRC_URI="https://github.com/gnosek/${PN}/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
fi
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~arm x86"
IUSE="systemd"
RDEPEND="
dev-libs/fcgi
systemd? ( sys-apps/systemd:= )
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
DOCS=( README.rst )
PATCHES=(
"${FILESDIR}"/${PN}-1.1.0-kill.patch
"${FILESDIR}"/${PN}-1.1.0-systemd.patch
"${FILESDIR}"/${PN}-1.1.0-uninit-ipv6.patch
)
src_prepare() {
default
sed -e "s/-Werror//" \
-i configure.ac || die "sed failed"
sed -e '/man8dir = $(DESTDIR)/s/@prefix@//' \
-i Makefile.in || die "sed failed"
tc-export CC
# Fix systemd units for Gentoo
sed -i -e '/User/d' systemd/fcgiwrap.service || die
sed -i -e '/Group/d' systemd/fcgiwrap.service || die
eautoreconf
}
src_configure() {
econf \
$(use_with systemd) \
--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
}
pkg_postinst() {
einfo "You may want to install www-servers/spawn-fcgi to use with fcgiwrap."
}
|
