blob: 3b69e327edd6f4a39ddd358fb0fdd276222f07ed (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools udev
DESCRIPTION="Library implementation for listing Vital Product Data"
HOMEPAGE="https://github.com/power-ras/libvpd"
SRC_URI="https://github.com/power-ras/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-2.1+"
SLOT="0"
KEYWORDS="ppc ppc64"
DEPEND="
dev-db/sqlite:3
sys-libs/zlib:=
"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}/2.2.8-gcc11.patch"
"${FILESDIR}/2.2.8-warnings.patch"
)
src_prepare() {
default
eautoreconf
}
src_configure() {
# sysconfdir is used only to establish where the udev rules file should go
# unfortunately it also adds the subdirs on its own so we strip it down to
# dirname
local myconf=(
--disable-static
--localstatedir="${EPREFIX}/var"
--sysconfdir="$( dirname $(get_udevdir) )"
)
econf "${myconf[@]}"
}
src_install() {
default
keepdir /var/lib/lsvpd
find "${D}" -name '*.la' -delete || die
}
|
