blob: 44b683ddf6bfd3ceac85d9cc5051c7ffe413b52f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 2004-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic toolchain-funcs
DESCRIPTION="Library for build EFI Applications"
HOMEPAGE="https://sourceforge.net/projects/gnu-efi/"
SRC_URI="mirror://sourceforge/gnu-efi/${P}.tar.bz2"
# inc/, lib/ dirs (README.efilib)
# - BSD-2
# gnuefi dir:
# - BSD (3-cluase): crt0-efi-ia32.S
# - GPL-2+ : setjmp_ia32.S
LICENSE="GPL-2+ BSD BSD-2"
SLOT="0"
KEYWORDS="-* ~amd64 ~arm ~arm64 ~ia64 ~x86"
IUSE="abi_x86_32 abi_x86_64 custom-cflags"
# These objects get run early boot (i.e. not inside of Linux),
# so doing these QA checks on them doesn't make sense.
QA_EXECSTACK="usr/*/lib*efi.a:* usr/*/crt*.o"
RESTRICT="strip"
PATCHES=( "${FILESDIR}"/${PN}-3.0.9-fix-clang-build.patch )
src_prepare() {
default
sed -i -e "s/-Werror//" Make.defaults || die
}
efimake() {
local arch=
case ${CHOST} in
arm*) arch=arm ;;
aarch64*) arch=aarch64 ;;
ia64*) arch=ia64 ;;
i?86*) arch=ia32 ;;
x86_64*) arch=x86_64 ;;
*) die "Unknown CHOST" ;;
esac
local args=(
ARCH="${arch}"
HOSTCC="${BUILD_CC}"
CC="${CC}"
AS="${AS}"
LD="${LD}"
AR="${AR}"
PREFIX="${EPREFIX}/usr"
LIBDIR='$(PREFIX)'/$(get_libdir)
)
emake -j1 "${args[@]}" "$@"
}
src_compile() {
tc-export BUILD_CC AR AS CC LD
if ! use custom-cflags; then
unset CFLAGS CPPFLAGS LDFLAGS
fi
if [[ ${CHOST} == x86_64* ]]; then
use abi_x86_32 && CHOST=i686 ABI=x86 efimake
use abi_x86_64 && efimake
else
efimake
fi
}
src_install() {
if [[ ${CHOST} == x86_64* ]]; then
use abi_x86_32 && CHOST=i686 ABI=x86 efimake INSTALLROOT="${D}" install
use abi_x86_64 && efimake INSTALLROOT="${D}" install
else
efimake INSTALLROOT="${D}" install
fi
einstalldocs
}
|
