blob: 6eb0ac441fed34e0c105b37d7a8c7453f28542f8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools prefix tmpfiles
DESCRIPTION="An authentication service for creating and validating credentials"
HOMEPAGE="https://github.com/dun/munge"
SRC_URI="https://github.com/dun/munge/releases/download/munge-${PV}/munge-${PV}.tar.xz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~alpha amd64 ~hppa ~ia64 ~mips ppc ppc64 ~riscv sparc x86"
IUSE="debug gcrypt static-libs"
DEPEND="
app-arch/bzip2
sys-libs/zlib
gcrypt? ( dev-libs/libgcrypt:0 )
!gcrypt? ( dev-libs/openssl:0= )
"
RDEPEND="
${DEPEND}
acct-group/munge
acct-user/munge
"
src_prepare() {
default
hprefixify config/x_ac_path_openssl.m4
eautoreconf
}
src_configure() {
local myeconfargs=(
--localstatedir="${EPREFIX}"/var
--with-crypto-lib=$(usex gcrypt libgcrypt openssl)
$(use_enable debug)
$(use_enable static-libs static)
)
econf "${myeconfargs[@]}"
}
src_install() {
local d
default
# Bug 450830
if [ -d "${ED}"/var/run ]; then
rm -rf "${ED}"/var/run || die
fi
dodir /etc/munge
keepdir /var/{lib,log}/munge
for d in "init.d" "default" "sysconfig"; do
if [ -d "${ED}"/etc/${d} ]; then
rm -r "${ED}"/etc/${d} || die
fi
done
newconfd "$(prefixify_ro "${FILESDIR}"/${PN}d.confd)" ${PN}d
newinitd "$(prefixify_ro "${FILESDIR}"/${PN}d.initd)" ${PN}d
if ! use static-libs; then
find "${D}" -name '*.la' -delete || die
fi
}
pkg_postinst() {
tmpfiles_process munge.conf
}
|
