blob: 5146d3cd56fc68fdf2c810f24dbf54523fc8c330 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
DOCS_BUILDER="doxygen"
DOCS_DEPEND="
dev-texlive/texlive-bibtexextra
dev-texlive/texlive-fontsextra
dev-texlive/texlive-fontutils
dev-texlive/texlive-latex
dev-texlive/texlive-latexextra
"
inherit python-single-r1 docs
MY_PV=$(ver_cut 1-3)
MY_PF=LHAPDF-${MY_PV}
DESCRIPTION="Les Houches Parton Density Function unified library"
HOMEPAGE="https://lhapdf.hepforge.org/"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://gitlab.com/hepcedar/lhapdf"
else
SRC_URI="https://www.hepforge.org/downloads/lhapdf/${MY_PF}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${MY_PF}"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2"
SLOT="0"
IUSE="examples +python"
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
RDEPEND="
dev-cpp/yaml-cpp
python? ( ${PYTHON_DEPS} )
"
DEPEND="${RDEPEND}"
BDEPEND="
python? (
$(python_gen_cond_dep '
>=dev-python/cython-0.19[${PYTHON_USEDEP}]
')
)
"
pkg_setup() {
use python && python-single-r1_pkg_setup
}
src_configure() {
local -x CONFIG_SHELL="${EPREFIX}/bin/bash"
econf \
--disable-static \
--with-yaml-cpp="${EPREFIX}/usr" \
$(use_enable python)
}
src_compile() {
emake all $(use doc && echo doxy)
}
src_test() {
emake -C tests
}
src_install() {
default
use doc && dodoc -r doc/doxygen/.
use examples && dodoc examples/*.cc
use python && python_optimize
find "${ED}" -name '*.la' -delete || die
}
|
