blob: c7756fee11c5427a44a4653cfb22d7f4790001a4 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
LUA_COMPAT=( lua5-{1..3} )
inherit autotools flag-o-matic lua-single toolchain-funcs
DESCRIPTION="Scalable Algorithms for Parallel Adaptive Mesh Refinement on Forests of Octrees"
HOMEPAGE="http://www.p4est.org/"
if [[ ${PV} = *9999* ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/cburstedde/${PN}.git"
EGIT_BRANCH="develop"
SRC_URI=""
else
SRC_URI="
https://github.com/cburstedde/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
https://github.com/cburstedde/libsc/archive/v${PV}.tar.gz -> libsc-${PV}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="GPL-2+"
SLOT="0"
# TODO petsc
IUSE="debug doc examples mpi openmp romio threads +vtk-binary"
REQUIRED_USE="${LUA_REQUIRED_USE}
romio? ( mpi )"
RDEPEND="${LUA_DEPS}
~sci-libs/libsc-${PV}[${LUA_SINGLE_USEDEP},mpi=,openmp=,romio=,threads=]
sys-apps/util-linux
virtual/blas
virtual/lapack
mpi? ( virtual/mpi[romio=] )"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
PATCHES=(
"${FILESDIR}"/${PN}-2.3-fix_aclocal.patch
"${FILESDIR}"/${PN}-2.3-add_soname.patch
)
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
lua-single_pkg_setup
}
src_prepare() {
default
# Inject libsc to get all parts of the build system...
if ! [[ ${PV} = *9999* ]]; then
rmdir "${S}/sc" || die "rmdir failed"
mv "${WORKDIR}/libsc-${PV}" "${S}/sc" || die "mv failed"
fi
# Inject a version number into the build system
echo "${PV}" > ${S}/.tarball-version
AT_M4DIR="${WORKDIR}/${P}/config ${WORKDIR}/${P}/sc/config"
eautoreconf
sed -i \
"s/P4EST_SC_DIR\/etc/P4EST_SC_DIR\/share\/libsc/" \
"${S}"/configure || die "sed failed"
sed -i \
"s#lib/libsc\.la#$(get_libdir)/libsc\.so#" \
"${S}"/configure || die "sed failed"
}
src_configure() {
# avoid underlinkage
append-libs -lsc
local myeconfargs=(
--disable-static
$(use_enable debug)
$(use_enable mpi)
$(use_enable openmp)
$(use_enable romio mpiio)
$(use_enable threads pthread)
$(use_enable vtk-binary)
--with-blas="$($(tc-getPKG_CONFIG) --libs blas)"
--with-lapack="$($(tc-getPKG_CONFIG) --libs lapack)"
--with-sc="${ESYSROOT}/usr"
)
econf "${myeconfargs[@]}"
}
src_install() {
default
use doc && dodoc -r doc/*
if use examples
then
docinto examples
dodoc -r example/*
docompress -x /usr/share/doc/${PF}/examples
else
# Remove compiled example binaries in case of -examples:
rm -r "${ED}"/usr/bin || die "rm failed"
fi
# Fix wrong installation paths:
dodir /usr/share/p4est
mv "${ED}"/usr/share/data "${ED}"/usr/share/p4est/data || die "mv failed"
mv "${ED}"/etc/* "${ED}"/usr/share/p4est || die "mv failed"
rmdir "${ED}"/etc/ || die "rmdir failed"
# no static archives
find "${ED}" -name '*.la' -delete || die
}
|
