blob: 874edba4504d39a43adcdd9a33224868a0f767e2 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
inherit flag-o-matic toolchain-funcs vcs-snapshot
DESCRIPTION="A reference-guided aligner for next-generation sequencing technologies"
HOMEPAGE="https://github.com/wanpinglee/MOSAIK"
SRC_URI="https://github.com/wanpinglee/MOSAIK/archive/5c25216d3522d6a33e53875cd76a6d65001e4e67.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
S="${WORKDIR}/${P}/src"
PATCHES=(
"${FILESDIR}"/${P}-remove-platform-code.patch
"${FILESDIR}"/${P}-fix-build-system.patch
"${FILESDIR}"/${P}-Wformat-security.patch
"${FILESDIR}"/${P}-gcc7.patch
)
src_configure() {
# readd default warning flags from build system
append-flags -Wall -Wno-char-subscripts
append-lfs-flags
export BLD_PLATFORM=linux
}
src_compile() {
emake \
CC=$(tc-getCC) \
CXX=$(tc-getCXX) \
CFLAGS="${CFLAGS}" \
CXXFLAGS="${CXXFLAGS}" \
CPPFLAGS="${CPPFLAGS}" \
LDFLAGS="${LDFLAGS}"
}
src_install() {
dobin bin/Mosaik*
dodoc ../README
insinto /usr/share/${PN}/examples
doins -r ../demo/.
}
|
