blob: e1b6dbb6184ed50528f0c5cd103e620466b26e6c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit flag-o-matic toolchain-funcs
DESCRIPTION="Burrows-Wheeler Alignment Tool, a fast short genomic sequence aligner"
HOMEPAGE="https://github.com/lh3/bwa/"
SRC_URI="https://github.com/lh3/bwa/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~x86 ~x64-macos"
DEPEND="sys-libs/zlib"
RDEPEND="
${DEPEND}
dev-lang/perl"
PATCHES=(
"${FILESDIR}"/${PN}-0.7.17-Makefile.patch
"${FILESDIR}"/${PN}-0.7.17-gcc-10.patch
)
DOCS=( NEWS.md README-alt.md README.md )
src_configure() {
# -Werror=lto-type-mismatch
# https://bugs.gentoo.org/862255
# https://github.com/lh3/bwa/issues/411
filter-lto
tc-export CC AR
}
src_install() {
dobin bwa
exeinto /usr/libexec/${PN}
doexe qualfa2fq.pl xa2multi.pl
einstalldocs
doman bwa.1
}
|
