blob: 3b224d9778a114c31a4476f5d1fc41d4f51ebe99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
# Upstream is moving tags repeatedly, then we use commit hash.
RELEASE_COMMIT="4088a6c394e7f2f785d2f5e175a4e916259bdb09"
inherit xdg cmake
DESCRIPTION="Seafile desktop client"
HOMEPAGE="https://www.seafile.com/ https://github.com/haiwen/seafile-client/"
SRC_URI="https://github.com/haiwen/${PN}/archive/${RELEASE_COMMIT}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${RELEASE_COMMIT}"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"
IUSE="shibboleth"
RDEPEND="dev-db/sqlite:3
dev-libs/glib:2
dev-libs/jansson:=
dev-libs/openssl:=
dev-qt/qtbase:6[dbus,gui,network,widgets]
dev-qt/qtwebengine:6[widgets]
dev-qt/qt5compat:6
>=net-libs/libsearpc-3.2.0_p1
~net-misc/seafile-${PV}
sys-libs/zlib
virtual/opengl
elibc_musl? ( sys-libs/fts-standalone )"
DEPEND="${RDEPEND}"
BDEPEND="dev-qt/qttools:6[linguist]"
PATCHES=(
"${FILESDIR}/${PN}-9.0.11-select-qt6.patch"
)
src_configure() {
local mycmakeargs=(
-DBUILD_SHIBBOLETH_SUPPORT="$(usex shibboleth)"
)
# 863554
use elibc_musl && mycmakeargs+=( -DCMAKE_CXX_STANDARD_LIBRARIES="-lfts" )
cmake_src_configure
}
|
