blob: 123086e0934713c1ec1c263cfc0147f77d15840d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools bash-completion-r1 flag-o-matic
MY_P=${PN}-${PV/_rc/rc}
DESCRIPTION="Mobile shell that supports roaming and intelligent local echo"
HOMEPAGE="https://mosh.org"
#SRC_URI="https://mosh.org/${P}.tar.gz"
SRC_URI="https://github.com/mobile-shell/mosh/releases/download/${MY_P}/${MY_P}.tar.gz"
S="${WORKDIR}"/${MY_P}
LICENSE="GPL-3"
SLOT="0"
if [[ ${PV} != *_rc* ]] ; then
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
fi
IUSE="+client examples +hardened nettle +server syslog ufw +utempter"
REQUIRED_USE="
|| ( client server )
examples? ( client )"
RDEPEND="
dev-libs/protobuf:=
sys-libs/ncurses:=
sys-libs/zlib
virtual/ssh
client? (
dev-lang/perl
dev-perl/IO-Tty
)
!nettle? ( dev-libs/openssl:= )
nettle? ( dev-libs/nettle:= )
utempter? (
sys-libs/libutempter
)"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
QA_CONFIGURE_OPTIONS="--disable-static"
# [0] - avoid sandbox-violation calling git describe in Makefile.
PATCHES=(
"${FILESDIR}"/${PN}-1.2.5-git-version.patch
)
src_prepare() {
default
eautoreconf
}
src_configure() {
MAKEOPTS+=" V=1"
# protobuf needs >=c++14
append-cxxflags -std=gnu++14
local myeconfargs=(
# We install it ourselves in src_install
--disable-completion
$(use_enable client)
$(use_enable server)
$(use_enable examples)
$(use_enable hardened hardening)
$(use_enable ufw)
$(use_enable syslog)
$(use_with utempter)
# We default to OpenSSL as upstream do
--with-crypto-library=$(usex nettle nettle openssl-with-openssl-ocb)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
for myprog in $(find src/examples -type f -perm /0111) ; do
newbin ${myprog} ${PN}-$(basename ${myprog})
elog "${myprog} installed as ${PN}-$(basename ${myprog})"
done
# bug #477384
dobashcomp conf/bash-completion/completions/mosh
}
|
