blob: fb2fb73747b58109d35b0c7b6815f121f8d3128e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit autotools
DESCRIPTION="The GNU SASL client, server, and library"
HOMEPAGE="https://www.gnu.org/software/gsasl/"
SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
# Before giving keywords (or ideally even bumping), please check https://www.gnu.org/software/gsasl/ to see
# if it's a stable release or not!
KEYWORDS="amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
IUSE="+client gcrypt gnutls idn kerberos nls ntlm +server static-libs"
REQUIRED_USE="|| ( client server )"
DEPEND="
!net-libs/libgsasl
gcrypt? ( dev-libs/libgcrypt:0= )
gnutls? ( net-libs/gnutls:= )
idn? ( net-dns/libidn:= )
kerberos? ( virtual/krb5 )
nls? ( >=sys-devel/gettext-0.18.1 )
ntlm? ( >=net-libs/libntlm-0.3.5 )
"
RDEPEND="${DEPEND}"
src_prepare() {
default
sed -i \
-e '/gl_WARN_ADD(\[-Werror/d' \
-e 's/ -Werror//' \
configure.ac || die
eautoreconf
}
src_configure() {
local krb5_impl="--with-gssapi-impl=no"
# Could do net-libs/libgssglue in future?
if use kerberos; then
krb5_impl="--with-gssapi-impl="
# These are the two providers of virtual/krb5
if has_version app-crypt/mit-krb5; then
krb5_impl+="mit"
else
krb5_impl+="heimdal"
fi
fi
local myeconfargs=(
--disable-valgrind-tests
--disable-rpath
--with-packager-bug-reports="https://bugs.gentoo.org"
--with-packager-version="r${PR}"
--with-packager="Gentoo Linux"
$(use_enable client)
$(use_enable server)
$(use_enable kerberos gssapi)
${krb5_impl}
$(use_enable kerberos gs2)
$(use_with gcrypt libgcrypt)
$(use_with gnutls)
$(use_enable nls)
$(use_with idn stringprep)
$(use_enable ntlm)
$(use_enable static-libs static)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
if ! use static-libs; then
rm -f "${ED}"/usr/lib*/lib*.la || die
fi
doman doc/gsasl.1 doc/man/*.3
}
|
