blob: ba92d9a6530fcb6a5a7fbf2c28305334ff8bcf99 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit toolchain-funcs
DESCRIPTION="Safecat implements qmail's maildir algorithm, safely copying standard input"
HOMEPAGE="http://www.jeenyus.net/linux/software/safecat.html"
SRC_URI="http://www.jeenyus.net/linux/software/${PN}/${P}.tar.gz"
SRC_URI+=" mirror://gentoo/${P}-clang-fixes.patch"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~hppa ~mips ~ppc ~sparc ~x86"
RESTRICT="test"
DEPEND="sys-apps/groff"
PATCHES=(
# applying maildir-patch
"${FILESDIR}"/safecat-1.11-gentoo.patch
# Fix parallel make errors
"${FILESDIR}"/${P}-makefile.patch
# Fix POSIX head/tail syntax
"${FILESDIR}"/${P}-head-tail-POSIX.patch
# Fix dup objects
"${FILESDIR}"/${P}-dup-obj-makefile.patch
# Headers
"${FILESDIR}"/${P}-include.patch
# Clang fixes
"${DISTDIR}"/${P}-clang-fixes.patch
# GCC15 fixes
"${FILESDIR}"/safecat-1.13-gcc15.patch
# Link fixes
"${FILESDIR}"/safecat-1.13-ar.patch
)
src_prepare() {
default
sed -ni '/man\|doc/!p' hier.c || die
}
src_configure() {
echo "/usr" > conf-root || die
# Verified that these are safe as of 2024/12/01.
echo "$(tc-getCC) ${CFLAGS} -Wno-discarded-qualifiers -Wno-misleading-indentation" > conf-cc || die
echo "$(tc-getCC) ${LDFLAGS}" > conf-ld || die
echo "$(tc-getAR)" > conf-ar || die
echo "$(tc-getRANLIB)" > conf-ranlib || die
}
src_install() {
# ${D} is not valid in src_configure
# Do not use DJB compiled installer anymore
#echo "${D}/usr" > conf-root || die
#emake setup check
dobin safecat maildir
einstalldocs
doman maildir.1 safecat.1
}
|
