blob: 3debbeee8199459393575f62cfcb0d12ebf45ee8 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
|
# Copyright 2018-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson
DESCRIPTION="Library for Reliable Internet Stream Transport (RIST) protocol"
HOMEPAGE="https://code.videolan.org/rist/librist"
SRC_URI="https://code.videolan.org/rist/librist/-/archive/v${PV}/librist-v${PV}.tar.bz2"
S="${WORKDIR}/librist-v${PV}"
LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~arm64"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-libs/cJSON
net-libs/mbedtls:0=
"
DEPEND="${RDEPEND}"
BDEPEND="virtual/pkgconfig"
src_configure() {
local emesonargs=(
-Dstatic_analyze=false
$(meson_use test)
-Dbuiltin_cjson=false
-Dbuiltin_mbedtls=false
# Tools have automagic libmicrohttpd dep for prometheus;
# needs solved before exposing; look into use_tun once enabled
-Dbuilt_tools=false
-Dfallback_builtin=false
-Duse_mbedtls=true
-Duse_nettle=false
-Duse_tun=false # Used only by tools
)
meson_src_configure
}
src_test() {
# multicast tests fails with FEATURES=network-sandbox
meson_src_test --no-suite multicast
}
|
