blob: 14144aaf22aa4df914294aa709ab130b03d9a4b3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
DESCRIPTION="C library for building NETCONF servers and clients"
HOMEPAGE="https://github.com/CESNET/libnetconf2"
SRC_URI="https://github.com/CESNET/libnetconf2/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 ~x86"
IUSE="doc test"
RESTRICT="!test? ( test )"
RDEPEND="
dev-libs/openssl:0=
>=net-libs/libyang-2.0.194
net-libs/libssh:0=[server]
virtual/libcrypt:="
DEPEND="${RDEPEND}
test? ( dev-util/cmocka )"
BDEPEND="
virtual/pkgconfig
doc? ( app-text/doxygen[dot] )"
src_configure() {
# fails tests, but only with LTO.
# [ ERROR ] --- 0 != 0xffffffffffffffff
# [ LINE ] --- /var/tmp/portage/net-libs/libnetconf2-2.1.31/work/libnetconf2-2.1.31/tests/client/test_client_ssh.c:716: error: Failure!
# [ FAILED ] test_nc_client_ssh_ch_add_bind_listen
#
# https://bugs.gentoo.org/877449
# https://github.com/CESNET/libnetconf2/issues/471
filter-lto
local mycmakeargs=(
-DENABLE_TESTS=$(usex test)
-DENABLE_VALGRIND_TESTS=OFF
)
cmake_src_configure
}
src_compile() {
cmake_src_compile
use doc && cmake_src_compile doc
}
src_install() {
cmake_src_install
use doc && dodoc -r doc/.
}
|
