blob: 82d39902f7c35151a3c1bba01af7b017c9b15f1d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools toolchain-funcs
DESCRIPTION="Implements functions designed to lock the standard mailboxes"
HOMEPAGE="https://github.com/miquels/liblockfile"
SRC_URI="https://github.com/miquels/liblockfile/archive/v${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="LGPL-2"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~x86-solaris"
IUSE="static-libs"
RDEPEND="acct-group/mail"
DEPEND="${RDEPEND}"
DOCS=( Changelog README )
PATCHES=(
"${FILESDIR}/${PN}-1.16-makefile.patch"
)
src_prepare() {
default
# I don't feel like making the Makefile portable
if [[ ${CHOST} == *-darwin* ]] ; then
cp "${FILESDIR}"/Makefile.Darwin.in Makefile.in || die
fi
eautoreconf
}
src_configure() {
local grp=mail
if use prefix ; then
# We never want to use LDCONFIG
export LDCONFIG=${EPREFIX}/bin/true
# In unprivileged installs this is "mail"
grp=$(id -g)
fi
local myeconfargs=(
--with-mailgroup=${grp}
--enable-shared
)
econf "${myeconfargs[@]}"
}
src_compile() {
emake AR="$(tc-getAR)"
}
src_install() {
default
if ! use static-libs ; then
find "${ED}" -type f -name "*.a" -delete || die
fi
}
|
