blob: 6e67a98dd294a890c60c51848dee0ab630445279 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PV="${PV/rc/}"
inherit autotools optfeature systemd tmpfiles
DESCRIPTION="Perl client used to update dynamic DNS entries"
HOMEPAGE="https://ddclient.net/"
SRC_URI="https://github.com/${PN}/${PN}/archive/refs/tags/v${MY_PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/${PN}-${MY_PV}"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
LICENSE="GPL-2+"
SLOT="0"
IUSE="examples selinux"
RDEPEND="
acct-group/ddclient
acct-user/ddclient
dev-lang/perl
dev-perl/Digest-SHA1
dev-perl/IO-Socket-INET6
dev-perl/IO-Socket-SSL
virtual/perl-Digest-SHA
virtual/perl-JSON-PP
selinux? ( sec-policy/selinux-ddclient )
"
src_prepare() {
default
# Remove PID setting, to reliably setup the environment for the init script
sed -e '/^pid/d' -i ddclient.conf.in || die
# Don't create cache directory, as it's created by init script / tmpfiles
sed -e '/MKDIR_P/d' -i Makefile.am || die
# Remove windows executable
if use examples; then
rm sample-etc_dhcpc_dhcpcd-eth0.exe || die
fi
eautoreconf
}
src_install() {
default
newinitd "${FILESDIR}"/ddclient.initd-r7 ddclient
systemd_newunit "${FILESDIR}"/ddclient.service-r2 ddclient.service
newtmpfiles "${FILESDIR}"/ddclient.tmpfiles-r1 ddclient.conf
if use examples; then
docinto examples
dodoc sample-*
fi
einstalldocs
}
pkg_postinst() {
if [[ ${REPLACING_VERSIONS} ]]; then
for v in ${REPLACING_VERSIONS}; do
if ver_test "${v}" -lt 3.10.0; then
cp /etc/ddclient/ddclient.conf /etc/ddclient.conf || die
ewarn "Your DDClient configuration has been copied from"
ewarn "'/etc/ddclient/ddclient.conf' to '/etc/ddclient.conf'."
ewarn "Please check your configuration."
break
fi
done
fi
optfeature "using iproute2 instead if ifconfig." sys-apps/iproute2
tmpfiles_process ddclient.conf
}
|
