blob: dfd692811b8d8163330faa9bb33ee29cf6495e15 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit meson
if [[ ${PV} == 9999 ]]; then
EGIT_REPO_URI="https://github.com/PipeWire/pipewire.git"
inherit git-r3
else
SRC_URI="https://github.com/PipeWire/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~arm64 ~ppc ~ppc64 ~x86"
fi
DESCRIPTION="Multimedia processing graphs"
HOMEPAGE="https://pipewire.org/"
LICENSE="LGPL-2.1+"
SLOT="0/0.2"
IUSE="bluetooth doc ffmpeg libav gstreamer sdl systemd vaapi X"
BDEPEND="
app-doc/xmltoman
doc? (
app-doc/doxygen
media-gfx/graphviz
)
"
DEPEND="
media-libs/alsa-lib
sys-apps/dbus
virtual/libudev
bluetooth? ( media-libs/sbc )
ffmpeg? (
!libav? ( media-video/ffmpeg:= )
libav? ( media-video/libav:= )
)
gstreamer? (
media-libs/gstreamer:1.0
media-libs/gst-plugins-base:1.0
)
sdl? ( media-libs/libsdl2 )
systemd? ( sys-apps/systemd )
vaapi? ( x11-libs/libva )
X? ( x11-libs/libX11 )
"
RDEPEND="${DEPEND}"
PATCHES=(
"${FILESDIR}"/${P}-alsa-lib-1.1.9.patch
"${FILESDIR}"/${P}-reuse-fd-in-pipewiresrc.patch
"${FILESDIR}"/${P}-fix-probing-without-starting.patch
"${FILESDIR}"/${P}-revert-combine-all-perms.patch
)
src_prepare() {
spa_use() {
if ! use ${1}; then
sed -e "/.*dependency.*'${2-$1}'/s/'${2-$1}'/'${2-$1}-disabled-by-USE-no-${1}'/" \
-i spa/meson.build || die
fi
}
default
spa_use bluetooth sbc
spa_use ffmpeg libavcodec
spa_use ffmpeg libavformat
spa_use ffmpeg libavfilter
spa_use vaapi libva
spa_use sdl sdl2
spa_use X x11
}
src_configure() {
local emesonargs=(
-Dman=true
$(meson_use doc docs)
$(meson_feature gstreamer)
$(meson_use systemd)
)
meson_src_configure
}
pkg_postinst() {
elog "Package has optional sys-auth/rtkit RUNTIME support that may be"
elog "disabled by setting DISABLE_RTKIT env var."
}
|
