blob: fe3b085f07dc6cd7ce1435679cd2b5a032b4e608 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake flag-o-matic
DESCRIPTION="GUI binding for using Coin/Open Inventor with Qt"
HOMEPAGE="https://github.com/coin3d/coin/wiki"
SRC_URI="https://github.com/coin3d/quarter/releases/download/v${PV}/${P}-src.tar.gz"
S="${WORKDIR}/quarter"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 x86"
IUSE="debug designer doc qch"
REQUIRED_USE="qch? ( doc )"
RDEPEND="
dev-qt/qtbase:6[gui,opengl,widgets]
dev-qt/qttools:6[widgets]
media-libs/coin
virtual/opengl
designer? ( dev-qt/qttools:6[designer] )
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
doc? (
app-text/doxygen[dot]
qch? ( dev-qt/qttools:6[assistant] )
)
"
PATCHES=(
"${FILESDIR}"/${PN}-1.2.1-cmake.patch
"${FILESDIR}"/${P}-find-qhelpgenerator.patch # bug 933432
)
DOCS=( AUTHORS NEWS README.md )
src_prepare() {
cmake_src_prepare
sed -e 's|/lib$|/lib@LIB_SUFFIX@|' \
-i Quarter.pc.cmake.in || die
}
src_configure() {
use debug && append-cppflags -DQUARTER_DEBUG=1
local mycmakeargs=(
-DCMAKE_INSTALL_DOCDIR="${EPREFIX}/usr/share/doc/${PF}"
-DQUARTER_BUILD_SHARED_LIBS=ON
-DQUARTER_BUILD_PLUGIN=$(usex designer)
-DQUARTER_BUILD_EXAMPLES=OFF
-DQUARTER_BUILD_DOCUMENTATION=$(usex doc)
-DQUARTER_BUILD_AWESOME_DOCUMENTATION=$(usex doc)
-DQUARTER_BUILD_DOC_MAN=$(usex doc)
-DQUARTER_BUILD_INTERNAL_DOCUMENTATION=OFF
-DQUARTER_BUILD_DOC_QTHELP=$(usex qch)
-DQUARTER_BUILD_DOC_CHM=OFF
-DQUARTER_USE_QT6=ON
)
use doc && mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Git=ON )
cmake_src_configure
}
|
