blob: 5979e0f489406adb410db6dac59453b0cef6b7c1 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
if [[ ${PV} == *9999* ]]; then
EGIT_REPO_URI="https://git.libreoffice.org/libzmf"
inherit git-r3 autotools
else
SRC_URI="http://dev-www.libreoffice.org/src/${PN}/${P}.tar.xz"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
fi
DESCRIPTION="Library for parsing Zoner Callisto/Draw documents"
HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libzmf"
LICENSE="MPL-2.0"
SLOT="0"
IUSE="debug doc test tools"
RESTRICT="!test? ( test )"
RDEPEND="
dev-libs/icu:=
dev-libs/librevenge
media-libs/libpng:0=
sys-libs/zlib
"
DEPEND="${RDEPEND}
dev-libs/boost
test? ( dev-util/cppunit )
"
BDEPEND="doc? ( app-doc/doxygen )"
src_prepare() {
default
[[ ${PV} == *9999* ]] && eautoreconf
}
src_configure() {
local myeconfargs=(
--disable-werror
$(use_enable debug)
$(use_with doc docs)
$(use_enable test tests)
$(use_enable tools)
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${ED}" -name '*.la' -delete || die
}
|
