blob: b44efadfb12ded60c0d5cc368dbc4d0cd5844e4f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
GREATEST_PV="1.2.1"
if [[ ${PV} = *9999 ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/ultravideo/kvazaar"
else
SRC_URI="https://github.com/ultravideo/kvazaar/archive/v${PV}.tar.gz -> ${P}.tar.gz
test? ( https://github.com/silentbicycle/greatest/archive/v${GREATEST_PV}.tar.gz -> greatest-${GREATEST_PV}.tar.gz )"
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv"
fi
inherit autotools multilib-minimal
DESCRIPTION="Open-source HEVC encoder"
HOMEPAGE="http://ultravideo.cs.tut.fi/ https://github.com/ultravideo/kvazaar"
LICENSE="LGPL-2.1"
# subslot = libkvazaar major
SLOT="0/6"
IUSE="static-libs test"
REQUIRED_USE="test? ( static-libs )"
RESTRICT="!test? ( test )"
ASM_DEP=">=dev-lang/yasm-1.2.0"
RDEPEND=""
DEPEND="${RDEPEND}
test? (
media-video/ffmpeg
media-video/hevc-hm
)
abi_x86_32? ( ${ASM_DEP} )
abi_x86_64? ( ${ASM_DEP} )
"
PATCHES=( "${FILESDIR}/${PN}-2.2.0-backport-pr377.patch" )
src_prepare() {
default
sed -e "/^dist_doc_DATA/s/COPYING //" -i Makefile.am || die
eautoreconf
if use test && [[ ${PV} != *9999 ]]; then
# https://bugs.gentoo.org/show_bug.cgi?id=595932
rmdir "${S}/greatest" || die
mv "${WORKDIR}/greatest-${GREATEST_PV}" "${S}/greatest" || die
fi
}
multilib_src_configure() {
ECONF_SOURCE="${S}" econf \
$(use_enable static-libs static)
}
multilib_src_test() {
KVZ_TEST_VALGRIND=0 emake check
}
multilib_src_install_all() {
find "${ED}" -name '*.la' -delete || die
}
|
