blob: 320768746102d3dabef5823036618422a56da8e7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="LXQt desktop panel and plugins"
HOMEPAGE="https://lxqt-project.org/"
MY_PV="$(ver_cut 1-2)"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/lxqt/${PN}.git"
else
SRC_URI="https://github.com/lxqt/${PN}/releases/download/${PV}/${P}.tar.xz"
KEYWORDS="amd64 arm64 ~ppc64 ~riscv ~x86"
fi
LICENSE="LGPL-2.1 LGPL-2.1+"
SLOT="0"
IUSE="
+alsa colorpicker cpuload +desktopswitch +directorymenu dom +kbindicator
+mainmenu +mount networkmonitor pulseaudio +quicklaunch lm-sensors +showdesktop
+spacer +statusnotifier sysstat +taskbar tray +volume +worldclock
"
# Work around a missing header issue: https://bugs.gentoo.org/666278
REQUIRED_USE="
|| ( desktopswitch mainmenu showdesktop taskbar )
volume? ( || ( alsa pulseaudio ) )
"
BDEPEND="
>=dev-qt/qttools-6.6:6[linguist]
>=dev-util/lxqt-build-tools-2.0.0
virtual/pkgconfig
"
DEPEND="
>=dev-libs/libqtxdg-4.0.0
>=dev-qt/qtbase-6.6:6[dbus,gui,widgets,xml]
>=dev-qt/qtsvg-6.6:6
kde-frameworks/kwindowsystem:6[X]
kde-plasma/layer-shell-qt:6
>=lxde-base/menu-cache-1.1.0
=lxqt-base/liblxqt-${MY_PV}*:=
=lxqt-base/lxqt-globalkeys-${MY_PV}*
=lxqt-base/lxqt-menu-data-${MY_PV}*
x11-libs/libX11
cpuload? ( sys-libs/libstatgrab )
kbindicator? ( x11-libs/libxkbcommon )
lm-sensors? ( sys-apps/lm-sensors:= )
mount? ( kde-frameworks/solid:6 )
networkmonitor? ( sys-libs/libstatgrab )
statusnotifier? (
dev-libs/libdbusmenu-lxqt
>=dev-qt/qtbase-6.6:6[concurrent]
)
sysstat? ( >=lxqt-base/libsysstat-1.0.0 )
tray? (
x11-libs/libxcb:=
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXrender
x11-libs/libXtst
x11-libs/xcb-util
x11-libs/xcb-util-image
)
volume? (
alsa? ( media-libs/alsa-lib )
pulseaudio? (
media-libs/libpulse
media-sound/pavucontrol-qt
)
)
"
RDEPEND="${DEPEND}"
src_configure() {
local mycmakeargs=(
# Plugins
-DCOLORPICKER_PLUGIN=$(usex colorpicker)
-DCPULOAD_PLUGIN=$(usex cpuload)
-DDESKTOPSWITCH_PLUGIN=$(usex desktopswitch)
-DDIRECTORYMENU_PLUGIN=$(usex directorymenu)
-DDOM_PLUGIN=$(usex dom)
-DKBINDICATOR_PLUGIN=$(usex kbindicator)
-DMAINMENU_PLUGIN=$(usex mainmenu)
-DMOUNT_PLUGIN=$(usex mount)
-DNETWORKMONITOR_PLUGIN=$(usex networkmonitor)
-DQUICKLAUNCH_PLUGIN=$(usex quicklaunch)
-DSENSORS_PLUGIN=$(usex lm-sensors)
-DSHOWDESKTOP_PLUGIN=$(usex showdesktop)
-DSPACER_PLUGIN=$(usex spacer)
-DSTATUSNOTIFIER_PLUGIN=$(usex statusnotifier)
-DSYSSTAT_PLUGIN=$(usex sysstat)
-DTASKBAR_PLUGIN=$(usex taskbar)
-DTRAY_PLUGIN=$(usex tray)
-DVOLUME_PLUGIN=$(usex volume)
-DWORLDCLOCK_PLUGIN=$(usex worldclock)
)
if use volume; then
mycmakeargs+=(
-DVOLUME_USE_ALSA=$(usex alsa)
-DVOLUME_USE_PULSEAUDIO=$(usex pulseaudio)
)
fi
cmake_src_configure
}
src_install() {
cmake_src_install
doman panel/man/*.1
}
|
