blob: cfe911015f905d4dd14972aa7d389ee5d16b5147 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit meson python-single-r1 xdg
DESCRIPTION="OS-native connector counterpart for GNOME Shell browser extension"
HOMEPAGE="https://wiki.gnome.org/Projects/GnomeShellIntegration"
SRC_URI="https://gitlab.gnome.org/nE0sIghT/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.gz"
S="${WORKDIR}/${PN}-v${PV}"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
DEPEND="${PYTHON_DEPS}
$(python_gen_cond_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]')
"
RDEPEND="${DEPEND}
gnome-base/gnome-shell
"
src_install() {
meson_src_install
python_fix_shebang "${D}/usr/bin/${PN}"
python_fix_shebang "${D}/usr/bin/${PN}-host"
python_optimize
if [[ $(get_libdir) != "lib" && "${SYMLINK_LIB}" != yes ]]; then
# Workaround www-client/firefox-bin manifests location
# Bug: https://bugs.gentoo.org/643522
insinto /usr/lib/mozilla/native-messaging-hosts
for id in chrome_gnome_shell browser_connector; do
doins "${ED}/usr/$(get_libdir)/mozilla/native-messaging-hosts/org.gnome.${id}.json"
done
fi
}
pkg_postinst() {
xdg_pkg_postinst
elog "Please note that this package provides OS-native connector only."
elog "You can install browser extension using link provided at"
elog "https://extensions.gnome.org website."
}
|
