blob: e07404cb11a4eb0b3ad063b243a4713c3625c76a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit cmake
DESCRIPTION="Unofficial GOG.com downloader for Linux"
HOMEPAGE="https://sites.google.com/site/gogdownloader/"
SRC_URI="https://github.com/Sude-/${PN}/releases/download/v${PV}/${P}.tar.gz"
LICENSE="WTFPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="gui qt5 qt6"
REQUIRED_USE="gui? ( ^^ ( qt5 qt6 ) )"
RDEPEND="
>=app-crypt/rhash-1.3.3-r2:0=
dev-cpp/htmlcxx:0=
dev-libs/boost:=[zlib]
>=dev-libs/jsoncpp-1.7:0=
dev-libs/tinyxml2:0=
>=net-misc/curl-7.55:0=[ssl]
gui? (
qt5? ( dev-qt/qtwebengine:5[widgets] )
qt6? ( dev-qt/qtwebengine:6[widgets] )
)
"
DEPEND="
${RDEPEND}
"
BDEPEND="
sys-apps/help2man
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${PN}-qt6.patch
)
src_configure() {
local mycmakeargs=(
-DUSE_QT_GUI=$(usex gui)
)
use gui && mycmakeargs+=(
-DCMAKE_DISABLE_FIND_PACKAGE_Qt6=$(usex qt5)
)
cmake_src_configure
}
src_install() {
cmake_src_install
gunzip "${ED}"/usr/share/man/man1/${PN}.1.gz || die
}
|
