blob: f49f59bcd447510500e9ebd2d171ed489560b397 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit desktop autotools
DESCRIPTION="Atari 800 emulator"
HOMEPAGE="https://atari800.github.io/"
SRC_URI="
https://github.com/atari800/atari800/releases/download/ATARI800_${PV//./_}/${P}-src.tgz
https://sourceforge.net/projects/${PN}/files/ROM/Original%20XL%20ROM/xf25.zip"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="opengl readline +sdl +sound"
REQUIRED_USE="opengl? ( sdl )"
RDEPEND="
sdl? (
>=media-libs/libsdl-1.2.0[opengl?,sound?,video]
)
!sdl? (
sys-libs/ncurses:=
)
readline? (
sys-libs/readline:=
sys-libs/ncurses:=
)
media-libs/libpng:=
sys-libs/zlib
"
DEPEND=${RDEPEND}
BDEPEND="
app-arch/unzip
"
src_prepare() {
default
# Bug 544608
eapply -p2 "${FILESDIR}/atari800-3.1.0-tgetent-detection.patch"
eautoreconf
}
src_configure() {
local video=ncurses
local sound=no
if use sdl; then
video=sdl
use sound && sound=sdl
elif use sound; then
sound=oss
fi
local myconf=(
$(use_with opengl)
$(use_with readline)
--with-video=${video}
--with-sound=${sound}
)
econf "${myconf[@]}"
}
src_install() {
default
insinto "/usr/share/${PN}"
doins "${WORKDIR}/"*.ROM
insinto /etc
newins "${FILESDIR}"/atari800-4.2.0.cfg atari800.cfg
newicon data/atari2.svg ${PN}.svg
make_desktop_entry ${PN} "Atari 800 emulator"
}
|
