blob: 0c974b7a9e8095a690dbd17236c43169057caa89 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LUA_COMPAT=( lua5-1 )
inherit autotools lua-single
DESCRIPTION="A collection of different plugins for Geany"
HOMEPAGE="https://plugins.geany.org"
SRC_URI="https://plugins.geany.org/${PN}/${P}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="amd64 arm ppc ppc64 ~riscv ~sparc x86"
IUSE="ctags debugger enchant git gpg gtkspell lua markdown nls pretty-printer scope webhelper workbench"
REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
DEPEND="
dev-libs/glib:2
>=dev-util/geany-2.0
x11-libs/gtk+:3
ctags? ( dev-util/ctags )
debugger? ( x11-libs/vte:2.91 )
enchant? ( app-text/enchant:= )
git? ( dev-libs/libgit2:= )
gpg? ( app-crypt/gpgme:= )
gtkspell? ( app-text/gtkspell:3= )
lua? ( ${LUA_DEPS} )
markdown? (
app-text/discount:=
net-libs/webkit-gtk:4.1
)
pretty-printer? ( dev-libs/libxml2:2 )
scope? ( x11-libs/vte:2.91 )
webhelper? ( net-libs/webkit-gtk:4.1 )
workbench? ( dev-libs/libgit2:= )
"
RDEPEND="${DEPEND}
scope? ( dev-debug/gdb )
"
BDEPEND="virtual/pkgconfig
nls? ( sys-devel/gettext )
"
PATCHES=(
"${FILESDIR}/${P}-gcc14.patch"
"${FILESDIR}/${P}-webkit2gtk-4.1.patch"
)
pkg_setup() {
use lua && lua-single_pkg_setup
}
src_prepare() {
default
eautoreconf
}
src_configure() {
local myeconfargs=(
--disable-cppcheck
--disable-extra-c-warnings
$(use_enable nls)
--enable-utilslib
# Plugins
--enable-addons
--enable-autoclose
--enable-automark
--enable-codenav
--enable-commander
--enable-defineformat
--enable-geanydoc
--enable-geanyextrasel
--enable-geanyinsertnum
--enable-geanymacro
--enable-geanyminiscript
--enable-geanynumberedbookmarks
--enable-geanyprj
--enable-geanyvc $(use_enable gtkspell)
--enable-keyrecord
--enable-latex
--enable-lineoperations
--enable-lipsum
--enable-overview
--enable-pairtaghighlighter
--enable-pohelper
--enable-projectorganizer
--enable-sendmail
--enable-shiftcolumn
--enable-tableconvert
--enable-treebrowser
--enable-vimode
--enable-xmlsnippets
$(use_enable debugger)
$(use_enable ctags geanyctags)
$(use_enable lua geanylua)
$(use_enable gpg geanypg)
$(use_enable git gitchangebar)
$(use_enable markdown) --disable-peg-markdown # using app-text/discount instead
$(use_enable pretty-printer)
$(use_enable scope)
$(use_enable enchant spellcheck)
$(use_enable webhelper)
$(use_enable workbench)
# GeanyGenDoc requires ctpl which isn’t yet in portage
--disable-geanygendoc
# Require libsoup-2.4 which conflicts with webkit2gtk-4.1
--disable-geniuspaste
--disable-updatechecker
)
econf "${myeconfargs[@]}"
}
src_install() {
default
find "${D}" -name '*.la' -delete || die
# make installs all translations if LINGUAS is empty
if [[ -z "${LINGUAS-x}" ]]; then
rm -r "${ED}/usr/share/locale/" || die
fi
}
|
