blob: 40985662f0058f2b448f6dc6869e4d975e270629 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
REAL_PN="${PN}-scheme"
REAL_PV="$(ver_cut 1-2)"
REAL_P="${REAL_PN}-${REAL_PV}"
inherit toolchain-funcs
DESCRIPTION="Minimal Scheme implementation for use as an extension language"
HOMEPAGE="http://synthcode.com/scheme/chibi/"
if [[ "${PV}" == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/ashinn/${REAL_PN}.git"
else
SRC_URI="https://github.com/ashinn/${REAL_PN}/archive/${REAL_PV}.tar.gz
-> ${P}.tar.gz"
S="${WORKDIR}/${REAL_P}"
KEYWORDS="~amd64 ~x86"
fi
LICENSE="BSD"
SLOT="0"
src_configure() {
tc-export CC
export PREFIX="${EPREFIX}/usr"
export LIBDIR="${EPREFIX}/usr/$(get_libdir)"
export SOLIBDIR="${EPREFIX}/usr/$(get_libdir)"
# If "ldconfig" exists it is ran, overwrite it with "LDCONFIG" variable.
export LDCONFIG="0"
}
src_install() {
default
dosym "${REAL_PN}" "/usr/bin/${PN}"
}
|
