blob: 7f2830ce2d40aa135c5edeaa71fc6ac0cd3582fc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{8..10} pypy3 )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
DESCRIPTION="Extensions to the Python standard library unit testing framework"
HOMEPAGE="https://github.com/testing-cabal/testtools"
SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos"
RDEPEND="
>=dev-python/extras-1.0.0[${PYTHON_USEDEP}]
dev-python/python-mimeparse[${PYTHON_USEDEP}]
>=dev-python/pbr-0.11[${PYTHON_USEDEP}]
dev-python/pyrsistent[${PYTHON_USEDEP}]
>=dev-python/six-1.4.0[${PYTHON_USEDEP}]
"
DEPEND="
test? (
>=dev-python/fixtures-1.3.0[${PYTHON_USEDEP}]
dev-python/testscenarios[${PYTHON_USEDEP}]
)
"
PDEPEND=">=dev-python/fixtures-1.3.0[${PYTHON_USEDEP}]"
PATCHES=(
"${FILESDIR}"/testtools-2.4.0-py39.patch
"${FILESDIR}"/testtools-2.4.0-py310.patch
"${FILESDIR}"/testtools-2.4.0-assertitemsequal.patch
)
distutils_enable_sphinx doc
distutils_enable_tests unittest
src_prepare() {
# eliminate unittest2 & traceback2
sed -i -e '/unittest2/d' -e '/traceback2/d' requirements.txt || die
# eliminate linecache2
sed -i -e 's/import linecache2 as linecache/import linecache/' \
testtools/tests/test_compat.py || die
# also conditional imports
find -name '*.py' -exec \
sed -i -e 's:unittest2:unittest:' {} + || die
sed -i -e 's/^traceback =.*/import traceback/' \
testtools/content.py || die
# py3.10 changed the output
sed -i -e 's:test_syntax_error:_&:' \
testtools/tests/test_testresult.py || die
distutils-r1_src_prepare
}
python_test() {
"${PYTHON}" -m testtools.run testtools.tests.test_suite ||
die "tests failed under ${EPYTHON}"
}
|
