blob: ada4553734a9c86ef4484cf6b7d9f5ee02842126 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
FORTRAN_NEEDED=fortran
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=meson-python
PYTHON_COMPAT=( pypy3 python3_{10..12} )
PYTHON_REQ_USE="threads(+)"
inherit flag-o-matic fortran-2 distutils-r1 multiprocessing
DESCRIPTION="Scientific algorithms library for Python"
HOMEPAGE="
https://scipy.org/
https://github.com/scipy/scipy/
https://pypi.org/project/scipy/
"
if [[ ${PV} == *9999* ]] ; then
inherit git-r3
# Need submodules, so git for now.
EGIT_REPO_URI="https://github.com/scipy/scipy"
EGIT_BRANCH="maintenance/$(ver_cut 1-2).x"
EGIT_SUBMODULES=( '*' )
else
inherit pypi
# Upstream is often behind with doc updates
#DOC_PV=${PV}
DOC_PV=1.11.0
SRC_URI+="
doc? (
https://docs.scipy.org/doc/${PN}-${DOC_PV}/${PN}-html-${DOC_PV}.zip
)"
if [[ ${PV} != *rc* ]] ; then
KEYWORDS="amd64 arm arm64 ~loong ppc64 ~riscv ~sparc x86"
fi
fi
LICENSE="BSD LGPL-2"
SLOT="0"
IUSE="doc +fortran test-rust"
# umfpack is technically optional but it's preferred to have it available.
DEPEND="
>=dev-python/numpy-1.21.6:=[lapack,${PYTHON_USEDEP}]
sci-libs/arpack:=
sci-libs/umfpack
virtual/cblas
>=virtual/lapack-3.8
"
RDEPEND="
${DEPEND}
dev-python/pillow[${PYTHON_USEDEP}]
"
BDEPEND="
dev-lang/swig
>=dev-python/cython-0.29.35[${PYTHON_USEDEP}]
>=dev-python/meson-python-0.12.1[${PYTHON_USEDEP}]
>=dev-python/pybind11-2.10.4[${PYTHON_USEDEP}]
>=dev-build/meson-1.1.0
!kernel_Darwin? ( dev-util/patchelf )
virtual/pkgconfig
doc? ( app-arch/unzip )
fortran? ( dev-python/pythran[${PYTHON_USEDEP}] )
test? (
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
test-rust? (
dev-python/pooch[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_unpack() {
default
if use doc; then
unzip -qo "${DISTDIR}"/${PN}-html-${DOC_PV}.zip -d html || die
fi
}
python_configure_all() {
# https://github.com/scipy/scipy/pull/19857
# Fixed in 1.13.0
filter-lto
DISTUTILS_ARGS=(
-Dblas=blas
-Dlapack=lapack
-Duse-pythran=$(usex fortran true false)
)
}
python_test() {
cd "${BUILD_DIR}/install$(python_get_sitedir)" || die
local EPYTEST_DESELECT=(
# Network
scipy/datasets/tests/test_data.py::TestDatasets::test_existence_all
scipy/datasets/tests/test_data.py::TestDatasets::test_ascent
scipy/datasets/tests/test_data.py::TestDatasets::test_face
scipy/datasets/tests/test_data.py::TestDatasets::test_electrocardiogram
# Precision issue with diff. blas?
scipy/optimize/tests/test__basinhopping.py::Test_Metropolis::test_gh7799
# Crashes with assertion, not a regression
# https://github.com/scipy/scipy/issues/19321
scipy/signal/tests/test_signaltools.py::test_lfilter_bad_object
# timeouts
scipy/sparse/linalg/tests/test_propack.py::test_examples
# hang or incredibly slow
scipy/optimize/tests/test_lsq_linear.py::TestBVLS::test_large_rank_deficient
scipy/optimize/tests/test_lsq_linear.py::TestTRF::test_large_rank_deficient
)
local EPYTEST_IGNORE=()
if ! has_version -b "dev-python/pooch[${PYTHON_USEDEP}]" ; then
EPYTEST_IGNORE+=(
scipy/datasets/tests/test_data.py
)
fi
case ${EPYTHON} in
pypy3)
EPYTEST_DESELECT+=(
# fd leaks in tests
# https://github.com/scipy/scipy/issues/19553
scipy/fft/_pocketfft/tests/test_real_transforms.py
# TODO
'scipy/special/tests/test_data.py::test_boost[<Data for expi: expinti_data_long_ipp-expinti_data_long>]'
)
;;
esac
epytest -n "$(makeopts_jobs)" --dist=worksteal scipy
}
python_install_all() {
use doc && local HTML_DOCS=( "${WORKDIR}"/html/. )
distutils-r1_python_install_all
}
|
