blob: 7a35ef4c30e9030c353be8fbc048e8c7e111f384 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3 python3_{8..11} )
inherit distutils-r1
DESCRIPTION="Manage .env files"
HOMEPAGE="https://github.com/theskumar/python-dotenv"
SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
DEPEND="
test? (
>=dev-python/click-5[${PYTHON_USEDEP}]
dev-python/mock[${PYTHON_USEDEP}]
>=dev-python/sh-1.09[${PYTHON_USEDEP}]
)
"
DOCS=( CHANGELOG.md README.md )
distutils_enable_tests pytest
python_test() {
local EPYTEST_IGNORE=()
# remove when https://github.com/theskumar/python-dotenv/pull/397
# is merged
if ! has_version "dev-python/ipython[${PYTHON_USEDEP}]"; then
EPYTEST_IGNORE+=(
tests/test_ipython.py
)
fi
epytest
}
python_install() {
distutils-r1_python_install
ln -s dotenv "${D}$(python_get_scriptdir)"/python-dotenv || die
}
src_install() {
distutils-r1_src_install
# Avoid collision with dev-ruby/dotenv (bug #798648)
mv "${ED}"/usr/bin/{,python-}dotenv || die
}
|
