blob: 33919d855b0459f5ab94c9d47877886812e33f46 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
# Copyright 2020-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( pypy3 python3_{10..13} )
inherit distutils-r1 pypi
DESCRIPTION="A client library for executing Jupyter notebooks"
HOMEPAGE="
https://nbclient.readthedocs.io/en/latest/
https://github.com/jupyter/nbclient/
https://pypi.org/project/nbclient/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 sparc x86"
RDEPEND="
>=dev-python/jupyter-client-6.1.12[${PYTHON_USEDEP}]
>=dev-python/jupyter-core-5.1.0[${PYTHON_USEDEP}]
>=dev-python/nbformat-5.0[${PYTHON_USEDEP}]
>=dev-python/traitlets-5.4[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/ipython[${PYTHON_USEDEP}]
>=dev-python/ipykernel-6.19.3[${PYTHON_USEDEP}]
dev-python/ipywidgets[${PYTHON_USEDEP}]
dev-python/nbconvert[${PYTHON_USEDEP}]
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
dev-python/testpath[${PYTHON_USEDEP}]
dev-python/xmltodict[${PYTHON_USEDEP}]
)
"
EPYTEST_XDIST=1
distutils_enable_tests pytest
PATCHES=(
# https://github.com/jupyter/nbclient/pull/317
"${FILESDIR}/${PN}-0.10.0-py313.patch"
)
python_test() {
local EPYTEST_DESELECT=(
# hangs?
'tests/test_client.py::test_run_all_notebooks[Interrupt.ipynb-opts6]'
)
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -p asyncio -p rerunfailures --reruns=3
}
|
