blob: 7a2737d549c2718a58600e36da1b8471e1e3ce72 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..12} )
inherit distutils-r1 pypi virtualx
DESCRIPTION="An ultra fast cross-platform multiple screenshots module in python using ctypes"
HOMEPAGE="
https://github.com/BoboTiG/python-mss/
https://pypi.org/project/mss/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="amd64 ~arm arm64 ~riscv x86"
BDEPEND="
test? (
dev-python/pytest-rerunfailures[${PYTHON_USEDEP}]
dev-python/pyvirtualdisplay[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
distutils_enable_sphinx docs/source dev-python/sphinx-rtd-theme
EPYTEST_IGNORE=(
# upstream tests for self-build, apparently broken by setuptools
# issuing deprecation warnings
src/tests/test_setup.py
)
EPYTEST_DESELECT=(
# unreliable `lsof -U | grep ...` tests
src/tests/test_leaks.py
)
src_prepare() {
sed -i -e '/--cov/d' setup.cfg || die
distutils-r1_src_prepare
}
src_test() {
virtx distutils-r1_src_test
}
|
