blob: 2c2a5c2e3791811e91c52764dbebba5456a03403 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python3_{7..10} pypy3 )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1
DESCRIPTION="A full-featured template engine for Python"
HOMEPAGE="https://jinja.palletsprojects.com/ https://pypi.org/project/Jinja2/"
# pypi tarball is missing tests
SRC_URI="https://github.com/pallets/jinja/archive/${PV}.tar.gz -> ${P}.tar.gz"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris"
IUSE="examples"
RDEPEND="
>=dev-python/markupsafe-2.0.0[${PYTHON_USEDEP}]
!dev-python/jinja:compat"
distutils_enable_sphinx docs \
dev-python/sphinx-issues \
dev-python/pallets-sphinx-themes
distutils_enable_tests pytest
# XXX: handle Babel better?
src_prepare() {
# avoid unnecessary dep on extra sphinxcontrib modules
sed -i '/sphinxcontrib.log_cabinet/ d' docs/conf.py || die
distutils-r1_src_prepare
}
python_install_all() {
if use examples ; then
docinto examples
dodoc -r examples/.
fi
distutils-r1_python_install_all
}
pkg_postinst() {
if ! has_version dev-python/Babel; then
elog "For i18n support, please emerge dev-python/Babel."
fi
}
|
