blob: b9f7a42007fc024c97ae976cf47838f324a0e82b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3 python3_{10..12} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 pypi
DESCRIPTION="IPython HTML widgets for Jupyter"
HOMEPAGE="
https://ipywidgets.readthedocs.io/
https://github.com/jupyter-widgets/ipywidgets/
https://pypi.org/project/ipywidgets/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
RDEPEND="
>=dev-python/comm-0.1.3[${PYTHON_USEDEP}]
>=dev-python/ipython_genutils-0.2.0[${PYTHON_USEDEP}]
>=dev-python/traitlets-4.3.1[${PYTHON_USEDEP}]
>=dev-python/widgetsnbextension-4.0.10[${PYTHON_USEDEP}]
"
BDEPEND="
test? (
dev-python/jsonschema[${PYTHON_USEDEP}]
)
"
PDEPEND="
>=dev-python/ipython-6.1.0[${PYTHON_USEDEP}]
"
distutils_enable_tests pytest
src_prepare() {
# upstream hack to autoconfigure ipywidgets in jupyter
# we don't have jupyterlab_widgets packaged
sed -i -e '/jupyterlab_widgets/d' setup.cfg || die
distutils-r1_src_prepare
}
python_test() {
local EPYTEST_DESELECT=()
case ${EPYTHON} in
pypy3)
EPYTEST_DESELECT+=(
# https://github.com/pypy/pypy/issues/4892
ipywidgets/widgets/tests/test_interaction.py::test_interact_noinspect
)
;;
esac
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest
}
|
