blob: 6ce76b7cb38a9d248dafc732bdc850419cf3b256 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( pypy3 python3_{10..13} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 pypi virtualx
DESCRIPTION="IPython Kernel for Jupyter"
HOMEPAGE="
https://github.com/ipython/ipykernel/
https://pypi.org/project/ipykernel/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~arm64-macos ~x64-macos"
RDEPEND="
>=dev-python/anyio-4.2.0[${PYTHON_USEDEP}]
>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
>=dev-python/jupyter-client-8.0.0[${PYTHON_USEDEP}]
>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
>=dev-python/nest-asyncio-1.4[${PYTHON_USEDEP}]
>=dev-python/packaging-22[${PYTHON_USEDEP}]
>=dev-python/psutil-5.7[${PYTHON_USEDEP}]
>=dev-python/pyzmq-25.0[${PYTHON_USEDEP}]
>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
"
# RDEPEND seems specifically needed in BDEPEND, at least jupyter
# bug #816486
# pytest-8 runs a small subset of tests, we allow newer for 3.13
# since a few tests are better than skipping entirely
BDEPEND="
${RDEPEND}
test? (
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/ipyparallel[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/trio[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_prepare() {
# debugpy is actually optional
sed -i -e '/debugpy/d' pyproject.toml || die
distutils-r1_src_prepare
}
python_compile() {
distutils-r1_python_compile
# Use python3 in kernel.json configuration, bug #784764
sed -i -e '/python3.[0-9]\+/s//python3/' \
"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
}
src_test() {
virtx distutils-r1_src_test
}
python_test() {
local EPYTEST_DESELECT=(
# hangs?
tests/test_eventloop.py::test_tk_loop
# flaky
tests/test_eventloop.py::test_qt_enable_gui
)
case ${EPYTHON} in
python3.13)
EPYTEST_DESELECT+=(
tests/test_embed_kernel.py
tests/test_kernelspec.py::test_install_kernelspec
tests/test_zmq_shell.py::test_zmq_interactive_shell
)
;;
esac
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -p anyio -p timeout
}
|
