blob: cdcf6cac54ed11a3c655cae2184caecf79f01c22 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
|
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 multiprocessing pypi
DESCRIPTION="Fast random access of gzip files in Python"
HOMEPAGE="
https://pypi.org/project/indexed-gzip/
https://github.com/pauldmccarthy/indexed_gzip/
"
LICENSE="ZLIB"
SLOT="0"
KEYWORDS="~amd64 ~x86"
RDEPEND="
sys-libs/zlib:=
"
DEPEND="
${RDEPEND}
"
BDEPEND="
dev-python/cython[${PYTHON_USEDEP}]
test? (
dev-python/numpy[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_prepare() {
# strip custom "clean" command that doesn't support "-a"
# https://bugs.gentoo.org/838955
# TODO: this can be removed once distutils-r1 stops using clean
sed -e '/cmdclass/d' -i setup.py || die
distutils-r1_src_prepare
}
src_compile() {
# This actually enables line tracing, so it fits USE=debug more.
if use debug; then
export INDEXED_GZIP_TESTING=1
fi
# Fix implicit dependency on numpy that is used to build test
# extensions.
if ! use test; then
local -x PYTHONPATH="${T}:${PYTHONPATH}"
cat >> "${T}"/numpy.py <<-EOF || die
raise ImportError("I am not here!")
EOF
fi
distutils-r1_src_compile
}
python_test() {
cd "${BUILD_DIR}/install$(python_get_sitedir)/indexed_gzip/tests" || die
epytest -n "$(makeopts_jobs)" --dist=worksteal
# temporary files and test extensions
# (to achieve equivalence with USE=-test)
rm ctest*.{c,gz,so,tmp} || die
}
|
