blob: 3e79f9006a153d10151ed3b2afe42b481dde0035 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Copyright 2019-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3 python3_{10..13} )
inherit distutils-r1
DESCRIPTION="A high-performance immutable mapping type for Python"
HOMEPAGE="
https://github.com/MagicStack/immutables/
https://pypi.org/project/immutables/
"
SRC_URI="
https://github.com/MagicStack/${PN}/archive/v${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
IUSE="+native-extensions"
distutils_enable_tests pytest
src_prepare() {
sed -i -e '/mypy/d' tests/conftest.py || die
distutils-r1_src_prepare
}
python_compile() {
# upstream controls NDEBUG explicitly
use debug && local -x DEBUG_IMMUTABLES=1
local -x IMMUTABLES_EXT=$(usex native-extensions 1 0)
distutils-r1_python_compile
}
python_test() {
local EPYTEST_IGNORE=(
tests/test_mypy.py
)
rm -rf immutables || die
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest
}
|
