blob: e1b37849a4d538f46ae2d8aa27efaf2cfa900eb6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( pypy3 python3_{10..13} )
inherit distutils-r1 optfeature
DESCRIPTION="A minimal low-level HTTP client"
HOMEPAGE="
https://www.encode.io/httpcore/
https://github.com/encode/httpcore/
https://pypi.org/project/httpcore/
"
SRC_URI="
https://github.com/encode/httpcore/archive/${PV}.tar.gz
-> ${P}.gh.tar.gz
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~loong ~mips ppc ppc64 ~riscv ~s390 sparc x86"
RDEPEND="
<dev-python/anyio-5[${PYTHON_USEDEP}]
dev-python/certifi[${PYTHON_USEDEP}]
<dev-python/h11-0.15[${PYTHON_USEDEP}]
<dev-python/h2-5[${PYTHON_USEDEP}]
=dev-python/sniffio-1*[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
test? (
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
dev-python/pytest-httpbin[${PYTHON_USEDEP}]
dev-python/socksio[${PYTHON_USEDEP}]
dev-python/trustme[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
dev-python/pytest-trio[${PYTHON_USEDEP}]
dev-python/trio[${PYTHON_USEDEP}]
' 3.{10..12})
)
"
distutils_enable_tests pytest
python_test() {
local opts=()
local EPYTEST_IGNORE=()
if ! has_version "dev-python/trio[${PYTHON_USEDEP}]"; then
opts+=( -k "not trio" )
EPYTEST_IGNORE+=(
tests/_async/test_connection_pool.py
)
fi
if ! has_version "dev-python/pytest-trio[${PYTHON_USEDEP}]"; then
opts+=( -m "not trio" -o addopts= )
fi
epytest "${opts[@]}"
}
pkg_postinst() {
optfeature "SOCKS support" dev-python/socksio
}
|
