blob: 34902abc4db6e37ff61504c0d4cdea069fc05c2e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
PYTHON_COMPAT=( python{2_7,3_6,3_7,3_8} )
inherit meson python-r1 xdg-utils
DESCRIPTION="A Python Interface to GStreamer"
HOMEPAGE="https://gstreamer.freedesktop.org/"
SRC_URI="https://gstreamer.freedesktop.org/src/${PN}/${P}.tar.xz"
LICENSE="LGPL-2+"
SLOT="1.0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="${PYTHON_DEPS}
>=media-libs/gstreamer-${PV}:1.0[introspection]
>=media-libs/gst-plugins-base-${PV}:1.0[introspection]
>=dev-python/pygobject-3.8:3[${PYTHON_USEDEP}]
"
DEPEND="${RDEPEND}"
BDEPEND="
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}"/${PV}-python3.8.patch
)
src_prepare() {
default
# Avoid building plugin - it must NOT be multi-python as gst-inspect will map in all libpython.so versions and crash or behave mysteriously.
# Python plugin support is of limited use (GIL gets in the way). If it's ever requested or needed, it should be a
# separate python-single-r1 media-plugins/gst-plugins-python package that only builds the plugin directory.
sed -e '/subdir.*plugin/d' -i meson.build || die
xdg_environment_reset
}
src_configure() {
configuring() {
meson_src_configure \
-Dpython="${EPYTHON}"
}
python_foreach_impl configuring
}
src_compile() {
python_foreach_impl meson_src_compile
}
src_test() {
python_foreach_impl meson_src_test
}
src_install() {
installing() {
meson_src_install
python_optimize
}
python_foreach_impl installing
}
|
