blob: ae0a09d7de534508b58ba48259bd0e69ffbee935 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_PN="CherryPy"
PYTHON_COMPAT=( python3_{10..13} pypy3 )
inherit distutils-r1 pypi
DESCRIPTION="CherryPy is a pythonic, object-oriented HTTP framework"
HOMEPAGE="
https://cherrypy.dev/
https://github.com/cherrypy/cherrypy/
https://pypi.org/project/CherryPy/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ppc ppc64 ~riscv ~s390 sparc x86"
IUSE="ssl test"
RDEPEND="
>=dev-python/cheroot-8.2.1[${PYTHON_USEDEP}]
>=dev-python/portend-2.1.1[${PYTHON_USEDEP}]
dev-python/more-itertools[${PYTHON_USEDEP}]
dev-python/zc-lockfile[${PYTHON_USEDEP}]
dev-python/jaraco-collections[${PYTHON_USEDEP}]
ssl? (
dev-python/pyopenssl[${PYTHON_USEDEP}]
)
"
BDEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
dev-python/routes[${PYTHON_USEDEP}]
dev-python/simplejson[${PYTHON_USEDEP}]
dev-python/objgraph[${PYTHON_USEDEP}]
dev-python/path[${PYTHON_USEDEP}]
dev-python/requests-toolbelt[${PYTHON_USEDEP}]
!sparc? (
net-misc/memcached
dev-python/pylibmc[${PYTHON_USEDEP}]
dev-python/pytest-services[${PYTHON_USEDEP}]
)
)
"
distutils_enable_tests pytest
python_prepare_all() {
sed -i -e '/cov/d' pytest.ini || die
# upstream has been using xfail to mark flaky tests, then added
# xfail_strict... not a good idea
sed -i -e '/xfail_strict/d' pytest.ini || die
distutils-r1_python_prepare_all
}
python_test() {
local EPYTEST_DESELECT=()
local opts=()
# These tests are gracefully skipped when pylibmc is missing but not
# if pytest-services is missing -- even though that's the only test
# using these fixtures.
if ! has_version "dev-python/pytest-services[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
cherrypy/test/test_session.py::MemcachedSessionTest
)
else
opts+=( -p pytest-services )
fi
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest "${opts[@]}"
}
|
