blob: e577553476bf3c448ec0ffd9b486fa61c3bd658d (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
|
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CARGO_OPTIONAL=1
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=standalone
PYTHON_COMPAT=( python3_{10..13} )
CRATES="
arrayref@0.3.9
arrayvec@0.7.6
autocfg@1.4.0
blake3@1.5.5
cc@1.2.2
cfg-if@1.0.0
constant_time_eq@0.3.1
crossbeam-deque@0.8.5
crossbeam-epoch@0.9.18
crossbeam-utils@0.8.20
either@1.13.0
heck@0.5.0
hex@0.4.3
indoc@2.0.5
libc@0.2.167
memmap2@0.9.5
memoffset@0.9.1
once_cell@1.20.2
portable-atomic@1.10.0
proc-macro2@1.0.92
pyo3-build-config@0.23.2
pyo3-ffi@0.23.2
pyo3-macros-backend@0.23.2
pyo3-macros@0.23.2
pyo3@0.23.2
quote@1.0.37
rayon-core@1.12.1
rayon@1.10.0
shlex@1.3.0
syn@2.0.90
target-lexicon@0.12.16
unicode-ident@1.0.14
unindent@0.2.3
"
inherit cargo distutils-r1
MY_P=blake3-py-${PV}
DESCRIPTION="Python bindings for the BLAKE3 cryptographic hash function"
HOMEPAGE="
https://github.com/oconnor663/blake3-py/
https://pypi.org/project/blake3/
"
SRC_URI="
https://github.com/oconnor663/blake3-py/archive/${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
rust? (
${CARGO_CRATE_URIS}
)
"
S=${WORKDIR}/${MY_P}
LICENSE="
|| ( CC0-1.0 Apache-2.0 )
rust? (
"
# Dependent crate licenses
LICENSE+="
Apache-2.0-with-LLVM-exceptions BSD-2 MIT Unicode-3.0
|| ( Apache-2.0 CC0-1.0 MIT-0 )
"
LICENSE+="
)
"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+rust"
BDEPEND="
rust? (
${RUST_DEPEND}
dev-util/maturin[${PYTHON_USEDEP}]
)
!rust? (
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/wheel[${PYTHON_USEDEP}]
)
test? (
dev-python/numpy[${PYTHON_USEDEP}]
)
"
QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/blake3/blake3.*.so"
distutils_enable_tests pytest
pkg_setup() {
use rust && rust_pkg_setup
}
src_unpack() {
# Do this unconditionally as it has sensible behaviour even
# w/ USE=-rust.
cargo_src_unpack
}
src_prepare() {
# sed the package name and version to improve compatibility
sed -e 's:blake3_experimental_c:blake3:' \
-e "s:0[.]0[.]1:${PV}:" \
-i c_impl/setup.py || die
distutils-r1_src_prepare
}
python_compile() {
local DISTUTILS_USE_PEP517=$(usex rust maturin setuptools)
if ! use rust; then
cd c_impl || die
fi
distutils-r1_python_compile
if ! use rust; then
cd - >/dev/null || die
fi
}
|
