blob: 56a207480f016096a7aceaec8c2941aadbb298ca (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
|
# Copyright 2022-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CARGO_OPTIONAL=1
DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=standalone
PYTHON_COMPAT=( python3_{10..13} )
CRATES="
arrayref@0.3.7
arrayvec@0.7.4
autocfg@1.1.0
bitflags@1.3.2
blake3@1.5.0
cc@1.0.83
cfg-if@1.0.0
constant_time_eq@0.3.0
crossbeam-deque@0.8.5
crossbeam-epoch@0.9.18
crossbeam-utils@0.8.19
either@1.9.0
heck@0.4.1
hex@0.4.3
indoc@2.0.4
libc@0.2.153
lock_api@0.4.11
memmap2@0.7.1
memoffset@0.9.0
once_cell@1.19.0
parking_lot@0.12.1
parking_lot_core@0.9.9
proc-macro2@1.0.78
pyo3-build-config@0.20.2
pyo3-ffi@0.20.2
pyo3-macros-backend@0.20.2
pyo3-macros@0.20.2
pyo3@0.20.2
quote@1.0.35
rayon-core@1.12.1
rayon@1.8.1
redox_syscall@0.4.1
scopeguard@1.2.0
smallvec@1.13.1
syn@2.0.48
target-lexicon@0.12.13
unicode-ident@1.0.12
unindent@0.2.3
windows-targets@0.48.5
windows_aarch64_gnullvm@0.48.5
windows_aarch64_msvc@0.48.5
windows_i686_gnu@0.48.5
windows_i686_msvc@0.48.5
windows_x86_64_gnu@0.48.5
windows_x86_64_gnullvm@0.48.5
windows_x86_64_msvc@0.48.5
"
inherit cargo distutils-r1
MY_P=blake3-py-${PV}
DESCRIPTION="Python bindings for the BLAKE3 cryptographic hash function"
HOMEPAGE="
https://github.com/oconnor663/blake3-py/
https://pypi.org/project/blake3/
"
SRC_URI="
https://github.com/oconnor663/blake3-py/archive/${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
rust? (
${CARGO_CRATE_URIS}
)
"
S=${WORKDIR}/${MY_P}
LICENSE="
|| ( CC0-1.0 Apache-2.0 )
rust? (
"
# Dependent crate licenses
LICENSE+="
Apache-2.0-with-LLVM-exceptions BSD-2 MIT Unicode-DFS-2016
|| ( Apache-2.0 CC0-1.0 )
"
LICENSE+="
)
"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+rust"
BDEPEND="
rust? (
${RUST_DEPEND}
dev-util/maturin[${PYTHON_USEDEP}]
)
!rust? (
dev-python/setuptools[${PYTHON_USEDEP}]
dev-python/wheel[${PYTHON_USEDEP}]
)
test? (
dev-python/numpy[${PYTHON_USEDEP}]
)
"
QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/blake3/blake3.*.so"
distutils_enable_tests pytest
pkg_setup() {
use rust && rust_pkg_setup
}
src_unpack() {
# Do this unconditionally as it has sensible behaviour even
# w/ USE=-rust.
cargo_src_unpack
}
src_prepare() {
local PATCHES=(
# https://github.com/oconnor663/blake3-py/pull/44
"${FILESDIR}/${P}-gcc14.patch"
)
# sed the package name and version to improve compatibility
sed -e 's:blake3_experimental_c:blake3:' \
-e "s:0[.]0[.]1:${PV}:" \
-i c_impl/setup.py || die
distutils-r1_src_prepare
}
python_compile() {
local DISTUTILS_USE_PEP517=$(usex rust maturin setuptools)
if ! use rust; then
cd c_impl || die
fi
distutils-r1_python_compile
if ! use rust; then
cd - >/dev/null || die
fi
}
|
