blob: 4c7b9b97eeb5cfa00653a1d12b45aac7ecaf135e (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_PN=APScheduler
PYTHON_COMPAT=( python3_{10..13} )
inherit distutils-r1 pypi
DESCRIPTION="In-process task scheduler with Cron-like capabilities"
HOMEPAGE="
https://github.com/agronholm/apscheduler/
https://pypi.org/project/APScheduler/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
RDEPEND="
>=dev-python/tzlocal-4[${PYTHON_USEDEP}]
"
BDEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
test? (
>=dev-python/anyio-4.5.2[${PYTHON_USEDEP}]
dev-python/pytz[${PYTHON_USEDEP}]
>=dev-python/sqlalchemy-1.4[${PYTHON_USEDEP}]
dev-python/tornado[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
PATCHES=(
# disable test fixtures using external servers (mongodb, redis...)
"${FILESDIR}"/apscheduler-3.11.0-external-server-tests.patch
)
python_test() {
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -p anyio
}
|
