summaryrefslogtreecommitdiff
path: root/dev-perl/Schedule-Cron-Events/Schedule-Cron-Events-1.960.0.ebuild
blob: 3fff382c280ee750ee02e5d594fcdb12d22d6233 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DIST_AUTHOR=ATOOMIC
DIST_VERSION=1.96
DIST_EXAMPLES=( "examples/*" )
inherit perl-module

DESCRIPTION="Take a line from a crontab and find out when events will occur"

SLOT="0"
KEYWORDS="~amd64"

RDEPEND="
	virtual/perl-Time-Local
	dev-perl/Set-Crontab
"
BDEPEND="${RDEPEND}
	virtual/perl-ExtUtils-MakeMaker
	test? (
		virtual/perl-Data-Dumper
		virtual/perl-Test
		virtual/perl-Test-Simple
		dev-perl/Test-Deep
	)
"

src_prepare() {
	perl-module_src_prepare
	mkdir "${S}"/examples/ || die
	mv "${S}/cron_event_predict.plx" "${S}/examples/cron_event_predict.plx" || die
	sed -i 's|^cron_event_predict.plx|examples/cron_event_predict.plx|' "${S}"/MANIFEST || die
	sed -i "/cron_event_predict.plx/d" Makefile.PL || die
}